(VBScript) Verify an RSA Signature Against the Signed String

See more Apple Keychain Examples

Note: This example requires Chilkat v11.0.0 or greater.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' Create the same string we previously signed in this example: 
' RSA Sign utf-8 Bytes of String to get Base64 RSA Signature

set sb = CreateObject("Chilkat.StringBuilder")
crlfLineEnding = 1

For i = 0 To 10
    success = sb.AppendLine("This is a test.",crlfLineEnding)
Next

base64_rsa_sig = "gWgpEXQqvXN6wh0MuFXPiw2xCb8cnmdizBT1TD1Tpm2GlJ8gnD59DGSj35GGXk1tM+mCOvMa2uW/9gmz8p6A90JLbn918i/2wKGvcde4wXnzPO7JADSNn2UwYzf3rp4/q/JrHv1GZETRJhABSFqTxOgdmdbEJQE/zijOSctCtQAM2CTb6t2BO8uHKSSUAwPH2cbeWxqsaVRLT4ruk5nZOxhoLgLMSjupiSzbE8zSTkkFOEHD+Mbb2xwg85AI0E4DsUnp+hLwwtS0blesgSyvtBY8oJODJeFcJsR7JDOTPdzHQHgJRl/2A4ij5xT91TpXy7ok43jhT6O9j7Q3qrafIQ=="

' Get the public key to be used for signature verification.
set pubKey = CreateObject("Chilkat.PublicKey")
success = pubKey.LoadFromFile("rsaKeys/chilkat-rsa-2048.pem")
If (success = 0) Then
    outFile.WriteLine(pubKey.LastErrorText)
    WScript.Quit
End If

set rsa = CreateObject("Chilkat.Rsa")
success = rsa.UsePublicKey(pubKey)
If (success = 0) Then
    outFile.WriteLine(rsa.LastErrorText)
    WScript.Quit
End If

' Verify the string against the signature.
' We signed the utf-8 byte representation of the string, so we must indicate
' to also validate against the utf-8 byte representation.
rsa.Charset = "utf-8"
rsa.EncodingMode = "base64"
signedString = sb.GetAsString()
success = rsa.VerifyStringENC(signedString,"sha256",base64_rsa_sig)

If (success = 0) Then
    outFile.WriteLine(rsa.LastErrorText)
    outFile.WriteLine("Signature invalid.")
Else
    outFile.WriteLine("Signature valid.")
End If


outFile.Close