VBScript

RSA Sign utf-8 Bytes of String to get Base64 RSA Signature

See more Apple Keychain Examples

Demonstrates how RSA sign the utf-8 byte representation of a string to get the signature in base64 format. VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' Assuming the smartcard/USB token is installed with the correct drivers from the manufacturer,
' this code can work on multiple platforms including Windows, MacOS, Linux, and iOS.

' Chilkat automatically detects and determines the way in which the HSM is used,
' which can be by PKCS11, Apple Keychain, Microsoft CNG / Crypto API, or ScMinidriver.

set cert = CreateObject("Chilkat.Cert")

' Set the token/smartcard PIN prior to loading.
cert.SmartCardPin = "123456"

' Specify the certificate by its common name.
success = cert.LoadFromSmartcard("cn=chilkat-rsa-2048")
If (success = 0) Then
    outFile.WriteLine(cert.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine("Signing with cert: " & cert.SubjectCN)

' Create a string to be hashed and signed.
set sb = CreateObject("Chilkat.StringBuilder")
crlfLineEnding = 1

For i = 0 To 10
    success = sb.AppendLine("This is a test.",crlfLineEnding)
Next

set rsa = CreateObject("Chilkat.Rsa")

' Use the certificate's private key for signing.
success = rsa.SetX509Cert(cert,1)
If (success = 0) Then
    outFile.WriteLine(rsa.LastErrorText)
    WScript.Quit
End If

' Sign the SHA-256 hash of the utf-8 byte representation of the contents of sb
' Return the signature in base64 format.
rsa.EncodingMode = "base64"
rsa.Charset = "utf-8"
stringToSign = sb.GetAsString()
sigBase64 = rsa.SignStringENC(stringToSign,"sha256")
If (rsa.LastMethodSuccess = 0) Then
    outFile.WriteLine(rsa.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine("RSA signature as base64: " & sigBase64)

outFile.Close