Xojo Plugin

XML NewChildBefore

Demonstrates the Chilkat.NewChildBefore method. Xojo Plugin

Dim success As Boolean
success = False

Dim xml As New Chilkat.Xml

xml.Tag = "order"
xml.NewChild2 "order_billing_info|price_list","Listino Italia"
xml.NewChild2 "order_billing_info|price_list_id","1"
xml.NewChild2 "order_billing_info|first_name","Francesco"

System.DebugLog(xml.GetXml())

// We now have the following XML:

// <?xml version="1.0" encoding="utf-8"?>
// <order>
//     <order_billing_info>
//         <price_list>Listino Italia</price_list>
//         <price_list_id>1</price_list_id>
//         <first_name>Francesco</first_name>
//     </order_billing_info>
// </order>

// If there is no "customer_id" element under "order_billing_info", then add it.
If (xml.HasChildWithTag("order_billing_info|customer_id") = True) Then
    System.DebugLog("customer_id already exists, nothing to do...")
    Return
End If

// Add the customer_id element just before the "price_list" element.

// Get the "order_billing_info" element
Dim orderBillingInfo As Chilkat.Xml
orderBillingInfo = xml.FindChild("order_billing_info")

// Call NewChildBefore to add an XML element <customer_id> before <price_list>
// First get the index of the element price_list
Dim index As Int32
index = orderBillingInfo.TagIndex("price_list")
System.DebugLog("index = " + Str(index))

// Add the "customer_id" element just before specified index.
Dim xCustId As Chilkat.Xml
xCustId = orderBillingInfo.NewChildBefore(index,"customer_id","1234")

System.DebugLog(xml.GetXml())

// We now have:

// <?xml version="1.0" encoding="utf-8"?>
// <order>
//     <order_billing_info>
//         <customer_id>1234</customer_id>
//         <price_list>Listino Italia</price_list>
//         <price_list_id>1</price_list_id>
//         <first_name>Francesco</first_name>
//     </order_billing_info>
// </order>