(Xojo Plugin) Streaming Compression --> Streaming Encryption

Demonstrate how to feed a compression stream into an encryption stream. This example does the following:

Data File --> Compress --> Encrypt --> Application Reads

Chilkat Xojo Plugin Download Xojo Plugin for Windows, Linux, Mac OS X, and ARM

//  This requires the Chilkat API to have been previously unlocked.
//  See Global Unlock Sample for sample code.

Dim success As Boolean

//  Initialize the compression object.
Dim compress As New Chilkat.Compression
compress.Algorithm = "deflate"

//  Initialize the encryption object.
Dim crypt As New Chilkat.Crypt2
crypt.CryptAlgorithm = "chacha20"
crypt.KeyLength = 256
crypt.EncodingMode = "hex"
Dim ivHex As String
ivHex = "000000000000000000000002"
crypt.SetEncodedIV ivHex,"hex"
crypt.InitialCount = 42
Dim keyHex As String
keyHex = "1c9240a5eb55d38af333888604f6b5f0473917c1402b80099dca5cbc207075c0"
crypt.SetEncodedKey keyHex,"hex"

//  Setup the streams.
//  streamC is for compression
Dim streamC As New Chilkat.Stream
//  streamE is for encryption
Dim streamE As New Chilkat.Stream

//  The source for the compressor is a file.
streamC.SourceFile = "qa_data/hamlet.xml"
//  The source for the encryptor is the output of the compressor stream.
success = streamE.SetSourceStream(streamC)

//  Our application will be reading the output of streamE.
//  Start the compression and encryption streams in background threads..
Dim taskC As Chilkat.Task
taskC = compress.CompressStreamAsync(streamC)
Dim taskE As Chilkat.Task
taskE = crypt.EncryptStreamAsync(streamE)
success = taskC.Run()
success = taskE.Run()

//  Read the compressed and encrypted bytes.
Dim outData As New Chilkat.BinData
While (streamE.EndOfStream <> True)
    If (streamE.DataAvailable = True) Then
        success = streamE.ReadBd(outData)
    End If

Wend

//  Let's make sure the background task finished.
//  It should already be the case that the task is finished.
While ((taskE.Finished <> True) Or (taskC.Finished <> True))
    taskE.SleepMs 20
Wend

//  Get any remaining data that needs to be flushed.
If (streamE.DataAvailable = True) Then
    success = streamE.ReadBd(outData)
End If

//  Double-check for success..
If (taskE.TaskSuccess <> True) Then
    System.DebugLog("async encryption failed:")
    System.DebugLog(taskE.ResultErrorText)
    success = False
End If

//  Double-check for success..
If (taskC.TaskSuccess <> True) Then
    System.DebugLog("async compression failed:")
    System.DebugLog(taskC.ResultErrorText)
    success = False
End If

//  Save the compressed/encrypted data to a file.
success = outData.WriteFile("qa_output/compressedEncrypted.dat")

System.DebugLog("The async compress/encrypt was successful.")

//  Let's decrypt and decompress to further verify...
success = crypt.DecryptBd(outData)
success = compress.DecompressBd(outData)

//  outData should contain the original data..
success = outData.WriteFile("qa_output/original_hamlet.xml")