(Xojo Plugin) RSA Encrypt and Decrypt Strings

Xojo Plugin sample code to RSA public-key encrypt and decrypt strings using public and private keys.

Chilkat Xojo Plugin Download Xojo Plugin for Windows, Linux, Mac OS X, and ARM

// This example assumes the Chilkat API to have been previously unlocked.
// See Global Unlock Sample for sample code.

Dim rsa As New Chilkat.Rsa

// This example also generates the public and private
// keys to be used in the RSA encryption.
// Normally, you would generate a key pair once,
// and distribute the public key to your partner.
// Anything encrypted with the public key can be
// decrypted with the private key.  The reverse is 
// also true: anything encrypted using the private
// key can be decrypted using the public key.

// Generate a 1024-bit key.  Chilkat RSA supports
// key sizes ranging from 512 bits to 4096 bits.
Dim success As Boolean
success = rsa.GenerateKey(1024)
If (success <> True) Then
    System.DebugLog(rsa.LastErrorText)
    Return
End If

// Keys are exported in XML format:
Dim publicKey As String
publicKey = rsa.ExportPublicKey()
Dim privateKey As String
privateKey = rsa.ExportPrivateKey()

Dim plainText As String
plainText = "Encrypting and decrypting should be easy!"

// Start with a new RSA object to demonstrate that all we
// need are the keys previously exported:
Dim rsaEncryptor As New Chilkat.Rsa

// Encrypted output is always binary.  In this case, we want
// to encode the encrypted bytes in a printable string.
// Our choices are "hex", "base64", "url", "quoted-printable".
rsaEncryptor.EncodingMode = "hex"

// We'll encrypt with the public key and decrypt with the private
// key.  It's also possible to do the reverse.
success = rsaEncryptor.ImportPublicKey(publicKey)

Dim usePrivateKey As Boolean
usePrivateKey = False
Dim encryptedStr As String
encryptedStr = rsaEncryptor.EncryptStringENC(plainText,usePrivateKey)
System.DebugLog(encryptedStr)

// Now decrypt:
Dim rsaDecryptor As New Chilkat.Rsa

rsaDecryptor.EncodingMode = "hex"
success = rsaDecryptor.ImportPrivateKey(privateKey)

usePrivateKey = True
Dim decryptedStr As String
decryptedStr = rsaDecryptor.DecryptStringENC(encryptedStr,usePrivateKey)

System.DebugLog(decryptedStr)