Xojo Plugin Requires Chilkat v11.7.0+

Password-Protect a PDF with AES-256 Encryption

See more PDF Protection Examples

Demonstrates the simplest way to encrypt a PDF so that it needs a password to open. The passwords come from the UserPassword and OwnerPassword properties, and Protection with the encrypt operation and an empty JSON uses the defaults: AES-256, everything encrypted, every permission granted. Protection only records the security the PDF will be saved with. Nothing is encrypted until WriteFile is called. Xojo Plugin

Dim success As Boolean
success = False

//  This example requires the Chilkat API to have been previously unlocked.
//  See Global Unlock Sample for sample code.

//  The PDF used in this example is available at two_page_memo.pdf

Dim pdf As New Chilkat.Pdf
success = pdf.LoadFile("qa_data/pdf/two_page_memo.pdf")
If (success = False) Then
    System.DebugLog(pdf.LastErrorText)
    Return
End If

//  The passwords are taken from these two properties at the time Protection is called.
//  The user password opens the PDF.  The owner password opens it too, and is the one needed
//  later to change or remove the protection.
pdf.UserPassword = "user-secret"
pdf.OwnerPassword = "owner-secret"

//  An empty JSON asks for the defaults: AES-256, everything encrypted, every permission granted.
Dim json As New Chilkat.JsonObject
Dim jsonOut As New Chilkat.JsonObject
success = pdf.Protection("encrypt",json,jsonOut)
If (success = False) Then
    System.DebugLog(pdf.LastErrorText)
    Return
End If

//  Nothing has been encrypted yet.  "pending" describes the security the PDF will be saved with.
System.DebugLog("algorithm: " + jsonOut.StringOf("pending.algorithm"))
System.DebugLog("PDF version: " + jsonOut.StringOf("pending.pdfVersion"))
System.DebugLog("password needed to open: " + Str(jsonOut.BoolOf("pending.userPasswordRequired")))

//  Writing the file applies it.
success = pdf.WriteFile("qa_output/memo_encrypted.pdf")
If (success = False) Then
    System.DebugLog(pdf.LastErrorText)
    Return
End If

//  PreLoadCheck reports a file's encryption without loading it, and needs no password.
Dim checker As New Chilkat.Pdf
Dim info As New Chilkat.JsonObject
success = checker.PreLoadCheck("qa_output/memo_encrypted.pdf",info)
If (success = False) Then
    System.DebugLog(checker.LastErrorText)
    Return
End If

System.DebugLog("encrypted: " + Str(info.BoolOf("encrypted")))
System.DebugLog("openPasswordRequired: " + Str(info.BoolOf("openPasswordRequired")))

//  With the password, the PDF opens normally.
Dim reader As New Chilkat.Pdf
reader.UserPassword = "user-secret"
success = reader.LoadFile("qa_output/memo_encrypted.pdf")
If (success = False) Then
    System.DebugLog(reader.LastErrorText)
    Return
End If

System.DebugLog("pages: " + Str(reader.NumPages))

//  Sample output:

//  algorithm: aes-256
//  PDF version: 1.7
//  password needed to open: True
//  encrypted: True
//  openPasswordRequired: True
//  pages: 2