Xojo Plugin Requires Chilkat v11.0.0+

Mastercard ICCP Get Data Source with OAuth1

See more Mastercard Examples

Demonstrates OAuth1 authentication with the Mastercard SOAP API's. This example sends a POST to the sandbox endpoint for the "In Control for Commercial Payments" (ICCP) API. Xojo Plugin

Dim success As Boolean
success = False

//  This example requires the Chilkat API to have been previously unlocked.
//  See Global Unlock Sample for sample code.

//  --------------------------------------------------------------------------------
//  Also see Chilkat's Online WSDL Code Generator
//  to generate code and SOAP Request and Response XML for each operation in a WSDL.
//  --------------------------------------------------------------------------------

//  First build the XML body of the SOAP request:

//      <soapenv:Envelope
//  	    xmlns:ser="http://mastercard.com/sd/pc/service"
//  	    xmlns:soapenv="http://schemas.xmlsoap.org/soap/envelope/">
//  	    <soapenv:Header>
//  	    </soapenv:Header>
//  	    <soapenv:Body>
//  		    <ser:getDataSourcesRequest></ser:getDataSourcesRequest>
//  	    </soapenv:Body>
//      </soapenv:Envelope>

//  Use this online tool to generate code from sample XML: 
//  Generate Code to Create XML

Dim xml As New Chilkat.Xml
xml.Tag = "soapenv:Envelope"
success = xml.AddAttribute("xmlns:ser","http://mastercard.com/sd/pc/service")
success = xml.AddAttribute("xmlns:soapenv","http://schemas.xmlsoap.org/soap/envelope/")
xml.UpdateChildContent "soapenv:Header",""
xml.UpdateChildContent "soapenv:Body|ser:getDataSourcesRequest",""

//  We'll need to get our signing RSA key from the PFX (provided by Mastercard)
Dim pfx As New Chilkat.Pfx
success = pfx.LoadPfxFile("qa_data/pfx/MCD_Sandbox_chilkat_iccp_API_Keys/chilkat_iccp-sandbox.p12","keystorepassword")
If (success = False) Then
    System.DebugLog(pfx.LastErrorText)
    Return
End If

Dim privKey As New Chilkat.PrivateKey
success = pfx.PrivateKeyAt(0,privKey)
If (success = False) Then
    System.DebugLog(pfx.LastErrorText)
    Return
End If

Dim http As New Chilkat.Http

http.OAuth1 = True
//  Use your own consumer key (this is not a valid consumer key)
http.OAuthConsumerKey = "MLBRl0-xxxxxxxxxxxxxxxxxxxxxxxxxx_BUNtu5xxxxx20b!a075a714a5fxxxxxxxxxxxxx59cd02b60000000000000000"
http.OAuthSigMethod = "RSA-SHA256"
success = http.SetOAuthRsaKey(privKey)
If (success = False) Then
    System.DebugLog(http.LastErrorText)
    Return
End If

//  Tell Chilkat to automatically calculate and add the oauth_body_hash field when sending the request.
http.OAuthBodyHash = True

//  Send the SOAP XML request and get the response.
//  Chilkat automaticaly adds the OAuth1 authentication.
Dim resp As New Chilkat.HttpResponse
success = http.HttpStr("POST","https://sandbox.api.mastercard.com/iccp/financial",xml.GetXml(),"utf-8","application/xml",resp)
If (success = False) Then
    System.DebugLog(http.LastErrorText)
    Return
End If

//  Examine the response status code and the XML response body.
System.DebugLog("Response status code = " + Str(resp.StatusCode))

Dim respXml As New Chilkat.Xml
success = resp.GetBodyXml(respXml)

System.DebugLog("Response XML:")
System.DebugLog(respXml.GetXml())

//  If desired, use this online tool to generate parsing code from response XML.
//  (Run your code once to get a representative sample response, and then generate the parsing code.)
//  Generate Parsing Code from XML