Xojo Plugin

Verify JWT Using an RSA Public Key (RS256, RS384, RS512)

See more JSON Web Token (JWT) Examples

Demonstrates how to verify a JWT that was signed using an RSA private key.

This example verifies the RSA signature. It also does the following:

• Checks to see if the time constraints ("nbf" and "exp") are valid.
• Recovers the original JOSE header.
• Recovers the original claims JSON.

Xojo Plugin

Dim success As Boolean
success = False

// Demonstrates how to verify an JWT using an RSA public key.

// This example requires the Chilkat API to have been previously unlocked.
// See Global Unlock Sample for sample code.

Dim pubKey As New Chilkat.PublicKey
success = pubKey.LoadFromFile("qa_data/pem/rsa_public.pem")

Dim jwt As New Chilkat.Jwt

Dim token As String
token = "eyJhbGciOiJSUzI1NiIsInR5cCI6IkpXVCJ9.eyJpc3MiOiJodHRwOi8vZXhhbXBsZS5vcmciLCJzdWIiOiJKb2huIiwiYXVkIjoiaHR0cDovL2V4YW1wbGUuY29tIiwiaWF0IjoxNDYzNDQ1MjM4LCJuYmYiOjE0NjM0NDUyMzgsImV4cCI6MTQ2MzQ0ODgzOH0.XRtqed6nuJ9lrp0wbNdDX3fCkSh_d9cHAniPbNcqm7G-5N3mtI5ntQvZBDP3pHtECVqufuDwW7XgUtzAi0ZXhyiRm1iZ3wMSN5lHWv52OQJmMHPA7VPd8Q1hDG-tx-QswzJKd75OEUHP7wIXq2Mg_YVElfDvJI6TGjGyS1y-RLHlz-ldlGsEwIBkO0PtzIYTVov97x8p9KCsPNhS4lZUIqKOYoTZUV5LpuAWARl-636DfMEB_A5_IEaw_W8leh2suP2ULVZxwE-Tk1kBC9tsSGrBrPTtg7sziaV4Lbb0JRANmh98uTRu5f8ji9CVOnpbMiAzjsJSy56kz_olweXSuA"

// First verify the signature.
Dim sigVerified As Boolean
sigVerified = jwt.VerifyJwtPk(token,pubKey)
System.DebugLog("verified: " + Str(sigVerified))

// Let's see if the time constraints, if any, are valid.
// The above JWT was created on the afternoon of 16-May-2016, with an expiration of 1 hour.
// If the current system time is before the "nbf" time, or after the "exp" time,
// then IsTimeValid will return false/0.
// Also, we'll allow a leeway of 60 seconds to account for any clock skew.
// Note: If the token has no "nbf" or "exp" claim fields, then IsTimeValid is always true.
Dim leeway As Int32
leeway = 60
Dim bTimeValid As Boolean
bTimeValid = jwt.IsTimeValid(token,leeway)
System.DebugLog("time constraints valid: " + Str(bTimeValid))

// Now let's recover the original claims JSON (the payload).
Dim payload As String
payload = jwt.GetPayload(token)
// The payload will likely be in compact form:
System.DebugLog(payload)

// We can format for human viewing by loading it into Chilkat's JSON object
// and emit.
Dim json As New Chilkat.JsonObject
success = json.Load(payload)
json.EmitCompact = False
System.DebugLog(json.Emit())

// We can recover the original JOSE header in the same way:
Dim joseHeader As String
joseHeader = jwt.GetHeader(token)
// The payload will likely be in compact form:
System.DebugLog(joseHeader)

// We can format for human viewing by loading it into Chilkat's JSON object
// and emit.
success = json.Load(joseHeader)
json.EmitCompact = False
System.DebugLog(json.Emit())