Xojo Plugin

JWE with DEFLATE Compression

See more JSON Web Encryption (JWE) Examples

Demonstrates how to DEFLATE ("zip") compress the JWE payload prior to encryption.

Note: This example requires Chilkat v9.5.0.66 or greater.

Xojo Plugin

Dim success As Boolean
success = False

// This requires the Chilkat API to have been previously unlocked.
// See Global Unlock Sample for sample code.

// Note: This example requires Chilkat v9.5.0.66 or greater.

// Create some plaintext to be encrypted.
// This example will demonstrate with and without DEFLATE (zip) compression.
Dim sbPlainText As New Chilkat.StringBuilder
Dim bCrLf As Boolean
bCrLf = True
Dim line As String
line = "Live long and prosper."
success = sbPlainText.AppendLine(line,bCrLf)
success = sbPlainText.AppendLine(line,bCrLf)
success = sbPlainText.AppendLine(line,bCrLf)
success = sbPlainText.AppendLine(line,bCrLf)

// The text to be encrypted:
System.DebugLog(sbPlainText.GetAsString())

Dim jwe As New Chilkat.Jwe

// Build the JWE Protected Header: {"alg":"A128KW","enc":"A128CBC-HS256","zip":"DEF"}
// The "zip":"DEF" parameter indicates that the plaintext payload should
// be compressed prior to encryption.
Dim jweProtHdr As New Chilkat.JsonObject
success = jweProtHdr.AppendString("alg","A128KW")
success = jweProtHdr.AppendString("enc","A128CBC-HS256")
success = jweProtHdr.AppendString("zip","DEF")
success = jwe.SetProtectedHeader(jweProtHdr)

// Set the AES key wrap key:
Dim aesWrappingKey As String
aesWrappingKey = "GawgguFyGrWKav7AX4VKUg"
success = jwe.SetWrappingKey(0,aesWrappingKey,"base64url")

// Encrypt and return the JWE in sbJweCompressed:
Dim sbJweCompressed As New Chilkat.StringBuilder
success = jwe.EncryptSb(sbPlainText,"utf-8",sbJweCompressed)
If (success <> True) Then
    System.DebugLog(jwe.LastErrorText)
    Return
End If

// Show the compressed JWE:
System.DebugLog(sbJweCompressed.GetAsString())
System.DebugLog("size of compressed JWE: " + Str(sbJweCompressed.Length))

// Now create a JWE without compression.
success = jweProtHdr.Delete("zip")
// Make sure to update the shared protected header:
success = jwe.SetProtectedHeader(jweProtHdr)

Dim sbJweUncompressed As New Chilkat.StringBuilder
success = jwe.EncryptSb(sbPlainText,"utf-8",sbJweUncompressed)
If (success <> True) Then
    System.DebugLog(jwe.LastErrorText)
    Return
End If

// Show the uncompressed JWE:
System.DebugLog(sbJweUncompressed.GetAsString())
System.DebugLog("size of uncompressed JWE: " + Str(sbJweUncompressed.Length))

// Decrypting is the same whether compression is used or not.
// The "zip" header in the JWE indicates that the payload should be 
// automatically decompressed (inflated) after decrypting.
Dim jwe2 As New Chilkat.Jwe
success = jwe2.LoadJweSb(sbJweCompressed)
If (success <> True) Then
    System.DebugLog(jwe2.LastErrorText)
    Return
End If

// Set the AES wrap key.
success = jwe2.SetWrappingKey(0,aesWrappingKey,"base64url")

// Decrypt (also automatically decompresses).
Dim sbOriginalText As New Chilkat.StringBuilder
success = jwe2.DecryptSb(0,"utf-8",sbOriginalText)
If (success <> True) Then
    System.DebugLog(jwe2.LastErrorText)
    Return
End If

System.DebugLog("original text from compressed JWE: ")
System.DebugLog(sbOriginalText.GetAsString())

// -----------------------------------------------------------
// Do the same with the uncompressed JWE

success = jwe2.LoadJweSb(sbJweUncompressed)
If (success <> True) Then
    System.DebugLog(jwe2.LastErrorText)
    Return
End If

// Set the AES wrap key.
success = jwe2.SetWrappingKey(0,aesWrappingKey,"base64url")

// Decrypt.
sbOriginalText.Clear 
success = jwe2.DecryptSb(0,"utf-8",sbOriginalText)
If (success <> True) Then
    System.DebugLog(jwe2.LastErrorText)
    Return
End If

System.DebugLog("original text from uncompressed JWE: ")
System.DebugLog(sbOriginalText.GetAsString())

// ------------------------------------------------
// The output of this example is:
// (Note: Your output data will be different because the content encryption key is randomly generated.)

// eyJhbGciOiJBMTI4S1ciLCJlbmMiOiJBMTI4Q0JDLUhTMjU2IiwiemlwIjoiREVGIn0.xuW-pEAIdEUFnk10m8ocursvktO8Of9ByCCAt6LgKkkOtCWCUn1kQw.zpGj-9WVni3cQxyOuZbcGA.0hzP1myua3oYpUHwCIY_3edBUREbUpLaX6wYuJduOdI.Ppc6aEO3y3B8BJ1FKMPjlA
// size of compressed JWE: 212
// eyJhbGciOiJBMTI4S1ciLCJlbmMiOiJBMTI4Q0JDLUhTMjU2In0.N4KeyC7nnSFkieJOyE24_zKeuV_m7v5UKoJb1TgV4Yc_r2RzUPNvyA.6AEdyXSCKx-iMmUJyypSLg.QpixfyrwhGpmwUDp623viik4smPav7vwPLiC2r-V-jwnSfEH3mxWu6DbrIz3mixaqATwynmEBzVPxvS9jTXpSAGCnniib4_0WoPl3r_wF5tlsKOEe--jpNso-DKd1Tp8jJxj3JkFWt3IRnUUKGj17g.sBfDwFc5fzpaI-UW8-SW4g
// size of uncompressed JWE: 303
// original text from compressed JWE: 
// Live long and prosper.
// Live long and prosper.
// Live long and prosper.
// Live long and prosper.
// 
// original text from uncompressed JWE: 
// Live long and prosper.
// Live long and prosper.
// Live long and prosper.
// Live long and prosper.
//