Xojo Plugin

Create a CAdES-T Signature

See more CAdES Examples

Demonstrates how to create a signature with an external timestamp that certifies the time of signing. This requires an online TSA (Time Stamping Authority) service that is capable of producing RFC 3161 compliant timestamps.

Note: This example requires Chilkat v9.5.0.78 or greater.

Xojo Plugin

Dim success As Boolean
success = False

// This example requires the Chilkat API to have been previously unlocked.
// See Global Unlock Sample for sample code.

Dim crypt As New Chilkat.Crypt2

// This example will use a certificate + private key from a .pfx/.p12 file.
// On Windows systems, it is also possible to use certs on smartcards/usb tokens or certs pre-installed in the Windows registry.
Dim cert As New Chilkat.Cert

Dim pfxPath As String
pfxPath = "qa_data/pfx/myCertAndKey.p12"
Dim pfxPassword As String
pfxPassword = "test123"

success = cert.LoadPfxFile(pfxPath,pfxPassword)
If (success <> True) Then
    System.DebugLog(cert.LastErrorText)
    Return
End If

success = crypt.SetSigningCert(cert)

// Use SHA-256 rather than the default of SHA-1
crypt.HashAlgorithm = "sha256"

// Create JSON that tells Chilkat what signing attributes to include:
Dim attrs As New Chilkat.JsonObject
success = attrs.UpdateBool("contentType",True)
success = attrs.UpdateBool("signingTime",True)
success = attrs.UpdateBool("messageDigest",True)
success = attrs.UpdateBool("signingCertificateV2",True)

// A CAdES-T signature is one that includes a timestampToken created by an online TSA (time stamping authority).
// We must include the TSA's URL, as well as a few options to indicate what is desired.
// Except for the TSA URL, the options shown here are typically what you would need.
success = attrs.UpdateBool("timestampToken.enabled",True)
success = attrs.UpdateString("timestampToken.tsaUrl","https://freetsa.org/tsr")
success = attrs.UpdateBool("timestampToken.addNonce",False)
success = attrs.UpdateBool("timestampToken.requestTsaCert",True)
success = attrs.UpdateString("timestampToken.hashAlg","sha256")

crypt.SigningAttributes = attrs.Emit()

Dim inFile As String
inFile = "qa_data/json/sample.json"
Dim outFile As String
outFile = "qa_output/sample_cades_t.p7m"

// This creates the CAdES-T signature.  During the signature creation, it
// communicates with the TSA to get a timestampToken.
success = crypt.CreateP7M(inFile,outFile)
If (success <> True) Then
    System.DebugLog(crypt.LastErrorText)
    Return
End If

System.DebugLog("Success.")