Xojo Plugin

Azure Storage: Download Blob to File

See more Azure Cloud Storage Examples

Sample code to download an Azure blob to a file. Xojo Plugin

Dim success As Boolean
success = False

// This example requires the Chilkat API to have been previously unlocked.
// See Global Unlock Sample for sample code.

Dim rest As New Chilkat.Rest

// Connect to the Azure Storage Blob Service
Dim bTls As Boolean
bTls = True
Dim port As Int32
port = 443
Dim bAutoReconnect As Boolean
bAutoReconnect = True
// In this example, the storage account name is "chilkat".
success = rest.Connect("chilkat.blob.core.windows.net",port,bTls,bAutoReconnect)
If (success <> True) Then
    System.DebugLog(rest.LastErrorText)
    Return
End If

// Provide Azure Cloud credentials for the REST call.
Dim azAuth As New Chilkat.AuthAzureStorage
azAuth.AccessKey = "AZURE_ACCESS_KEY"
// The account name used here should match the 1st part of the domain passed in the call to Connect (above).
azAuth.Account = "chilkat"
azAuth.Scheme = "SharedKey"
azAuth.Service = "Blob"
// This causes the "x-ms-version: 2021-08-06" header to be automatically added.
azAuth.XMsVersion = "2021-08-06"
success = rest.SetAuthAzureStorage(azAuth)

// Note: The application does not need to explicitly set the following
// headers: Content-Length, x-ms-date, Authorization.  These headers
// are automatically set by Chilkat.

// Setup a file stream for the download
Dim fileStream As New Chilkat.Stream
fileStream.SinkFile = "C:/temp/qa_output/starfish.jpg"

// Indicate that the call to FullRequestNoBody should send the response body
// to fileStream if the response status code is 200.
// If a non-success response status code is received, then nothing
// is streamed to the output file and the error response is returned by FullRequestNoBody.
Dim expectedStatus As Int32
expectedStatus = 200
success = rest.SetResponseBodyStream(expectedStatus,True,fileStream)

// The Azure blob container is "test", the file is "starfish.jpg"
Dim responseStr As String
responseStr = rest.FullRequestNoBody("GET","/test/starfish.jpg")
If (rest.LastMethodSuccess <> True) Then

    // Examine the request/response to see what happened.
    System.DebugLog("response status code = " + Str(rest.ResponseStatusCode))
    System.DebugLog("response status text = " + rest.ResponseStatusText)
    System.DebugLog("response header: " + rest.ResponseHeader)
    System.DebugLog("response body (if any): " + responseStr)
    System.DebugLog("---")
    System.DebugLog("LastRequestStartLine: " + rest.LastRequestStartLine)
    System.DebugLog("LastRequestHeader: " + rest.LastRequestHeader)
    Return
End If

System.DebugLog("Success.")