VBScript Requires Chilkat v11.0.0+

Iterate Over ZIP Entries Using EntryAt

This example demonstrates how to use the EntryAt method to iterate over all entries contained within a ZIP archive.

The EntryAt method retrieves a ZipEntry object for a given zero-based index.

This is useful for:

• Enumerating all entries in a ZIP archive
• Inspecting filenames, sizes, and timestamps
• Searching or filtering ZIP contents

Suppose the ZIP archive contains:

docs/readme.txt
images/logo.png
data/config.json

The example loops through all ZIP entries and prints information about each entry.

VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

'  Open an existing ZIP archive.
set zip = CreateObject("Chilkat.Zip")

success = zip.OpenZip("example.zip")
If (success = 0) Then
    outFile.WriteLine(zip.LastErrorText)
    WScript.Quit
End If

'  Get the total number of entries in the ZIP archive.
numEntries = zip.NumEntries

outFile.WriteLine("Number of ZIP entries = " & numEntries)

'  Create a ZipEntry object that will be reused
'  for each entry retrieved by EntryAt.
set entry = CreateObject("Chilkat.ZipEntry")

'  Iterate over all ZIP entries.
i = 0
Do While i < numEntries

    '  Retrieve the entry at index i.
    success = zip.EntryAt(i,entry)
    If (success = 0) Then
        outFile.WriteLine(zip.LastErrorText)
        WScript.Quit
    End If

    outFile.WriteLine("Entry " & i)
    outFile.WriteLine("  FileName: " & entry.FileName)
    outFile.WriteLine("  Uncompressed Length: " & entry.UncompressedLength)
    outFile.WriteLine("  Compressed Length: " & entry.CompressedLength)
    outFile.WriteLine("")

    i = i + 1
Loop

'  Sample output:
'  
'  Entry 0
'    FileName: docs/readme.txt
'    Uncompressed Length: 1204
'    Compressed Length: 512
'  
'  Entry 1
'    FileName: images/logo.png
'    Uncompressed Length: 84211
'    Compressed Length: 84102
'  

zip.CloseZip 

outFile.WriteLine("Done.")

outFile.Close