VBScript

Yubikey RSA Encrypt/Decrypt

See more RSA Examples

Demonstrates how to do RSA decryption using a private key stored on a Yubikey (or other USB token or smartcard).

Note: RSA encryption uses the public key, which is freely exportable and does not need to occur on the token/smartcard.

VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' This example assumes you have a certificate with private key on the Yubikey token.
' When doing simple RSA encryption/decryption, we don't actually need the certificate,
' but we'll be using the private key associated with the certificate.
' 
' The sensitive/secret material that needs to be kept private is the private key.
' The certificate itself and the public key can be freely shared.
' 

' We're going to encrypt and decrypt 32-bytes of data.
set bd = CreateObject("Chilkat.BinData")
success = bd.AppendEncoded("000102030405060708090A0B0C0D0E0F","hex")
success = bd.AppendEncoded("000102030405060708090A0B0C0D0E0F","hex")

' Let's get the desired cert.
' For this example, a self-signed certificate with a 2048-bit RSA key was generated in slot 9A.
set cert = CreateObject("Chilkat.Cert")

' Force Chilkat to use PKCS11 over ScMinidriver (if on Windows) and Apple Keychain (if on MacOS)
cert.UncommonOptions = "NoScMinidriver,NoAppleKeychain"

cert.SmartCardPin = "123456"

success = cert.LoadFromSmartcard("cn=chilkat_test_2048")
If (success = 0) Then
    outFile.WriteLine(cert.LastErrorText)
    WScript.Quit
End If

' RSA encrypt using the public key.
set rsa = CreateObject("Chilkat.Rsa")

' Provide the RSA object with the certificate on the Yubkey.
success = rsa.SetX509Cert(cert,1)
If (success = 0) Then
    outFile.WriteLine(rsa.LastErrorText)
    WScript.Quit
End If

' RSA encrypt using the public key.
usePrivateKey = 0
success = rsa.EncryptBd(bd,usePrivateKey)
If (success = 0) Then
    outFile.WriteLine(rsa.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine("RSA Encrypted Output in Hex:")
outFile.WriteLine(bd.GetEncoded("hex"))

' Now let's decrypt, using the private key on the Yubikey.
usePrivateKey = 1
success = rsa.DecryptBd(bd,usePrivateKey)
If (success = 0) Then
    outFile.WriteLine(rsa.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine("RSA Decrypted Output in Hex:")
outFile.WriteLine(bd.GetEncoded("hex"))

outFile.Close