(VBScript) Verify SSL Server Certificate

Demonstrates how to connect to an SSL server and verify its SSL certificate.

Note: This example requires Chilkat v11.0.0 or greater.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

set socket = CreateObject("Chilkat.Socket")

ssl = 1
maxWaitMillisec = 20000

' The SSL server hostname may be an IP address, a domain name,
' or "localhost". 

sslServerHost = "www.paypal.com"
sslServerPort = 443

' Connect to the SSL server:
success = socket.Connect(sslServerHost,sslServerPort,ssl,maxWaitMillisec)
If (success = 0) Then
    outFile.WriteLine(socket.LastErrorText)
    WScript.Quit
End If

set cert = CreateObject("Chilkat.Cert")

success = socket.GetServerCert(cert)
If (success <> 0) Then

    outFile.WriteLine("Server Certificate:")
    outFile.WriteLine("Distinguished Name: " & cert.SubjectDN)
    outFile.WriteLine("Common Name: " & cert.SubjectCN)
    outFile.WriteLine("Issuer Distinguished Name: " & cert.IssuerDN)
    outFile.WriteLine("Issuer Common Name: " & cert.IssuerCN)

    bExpired = cert.Expired
    bRevoked = cert.Revoked
    bSignatureVerified = cert.SignatureVerified
    bTrustedRoot = cert.TrustedRoot

    outFile.WriteLine("Expired: " & bExpired)
    outFile.WriteLine("Revoked: " & bRevoked)
    outFile.WriteLine("Signature Verified: " & bSignatureVerified)
    outFile.WriteLine("Trusted Root: " & bTrustedRoot)

End If

' Close the connection with the server
' Wait a max of 20 seconds (20000 millsec)
success = socket.Close(20000)

outFile.Close