VBScript

SSH Tunnel Set Allowed SSH Algorithms

Demonstrates the Chilkat SshTunnel.SetAllowedAlgorithms method, which restricts the SSH connection to a specific set of algorithms. A JsonObject supplies comma-separated allow-lists for the kex, hostKey, cipher, and mac categories. It must be called before Connect.

Important: You typically should not set allowed algorithms explicitly. By default Chilkat orders algorithms according to best practices and accounts for known vulnerabilities.

Background: SSH negotiates a mutually supported algorithm from each category at connection time, and pinning that choice makes an application brittle: if the server later drops a weak algorithm, the two sides may fail to agree and the tunnel stops working. The legitimate reasons to override are a security policy mandating specific algorithms or a compatibility problem with an old server; otherwise let the library's defaults evolve with current guidance.

Chilkat VBScript Downloads

Download Chilkat for VBScript

VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

'  Demonstrates the SshTunnel.SetAllowedAlgorithms method, which restricts the SSH connection to a
'  specific set of algorithms.  The only argument is a JsonObject.  It must be called before
'  Connect.
'  
'  Note: You typically should NOT set allowed algorithms explicitly.  By default Chilkat orders
'  algorithms according to best practices and accounts for known vulnerabilities.  Hard-coding
'  them can make an application brittle if a server later changes its allowed algorithms.

set tunnel = CreateObject("Chilkat.SshTunnel")

'  List the allowed algorithms for each category, in order of preference.
set json = CreateObject("Chilkat.JsonObject")
success = json.UpdateString("kex","curve25519-sha256@libssh.org,ecdh-sha2-nistp256")
success = json.UpdateString("hostKey","ssh-ed25519,ecdsa-sha2-nistp256")
success = json.UpdateString("cipher","chacha20-poly1305@openssh.com,aes256-ctr")
success = json.UpdateString("mac","hmac-sha2-256,hmac-sha2-512")

'  Apply the allow-list before connecting.
success = tunnel.SetAllowedAlgorithms(json)
If (success = 0) Then
    outFile.WriteLine(tunnel.LastErrorText)
    WScript.Quit
End If

tunnel.DestHostname = "db.internal.example.com"
tunnel.DestPort = 5432

sshPort = 22
success = tunnel.Connect("ssh.example.com",sshPort)
If (success = 0) Then
    outFile.WriteLine(tunnel.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine("Connected.")

waitForThreadExit = 1
success = tunnel.CloseTunnel(waitForThreadExit)
If (success = 0) Then
    outFile.WriteLine(tunnel.LastErrorText)
    WScript.Quit
End If


outFile.Close