VBScript

Check if the SSH Tunnel's Transport is Connected

Demonstrates the Chilkat SshTunnel.IsSshConnected method, which returns whether the SSH transport used by the tunnel is connected. It takes no arguments.

Background: A tunnel has two independent parts: the SSH transport to the server and the local listener that accepts connections to forward. This method reports only the first. The distinction matters because the listener can keep accepting local connections even after the SSH transport has dropped — those connections would then fail to forward — so a health check on a long-running tunnel should verify the SSH side explicitly.

Chilkat VBScript Downloads

Download Chilkat for VBScript

VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

'  Demonstrates the SshTunnel.IsSshConnected method, which returns whether the SSH transport used
'  by the tunnel is connected.  It takes no arguments.

set tunnel = CreateObject("Chilkat.SshTunnel")

'  The tunnel forwards accepted local connections to this destination through the SSH server.
tunnel.DestHostname = "db.internal.example.com"
tunnel.DestPort = 5432

'  Connect to the SSH server.  This performs the TCP/proxy connection and SSH handshake, but
'  does not authenticate yet.
sshPort = 22
success = tunnel.Connect("ssh.example.com",sshPort)
If (success = 0) Then
    outFile.WriteLine(tunnel.LastErrorText)
    WScript.Quit
End If

'  Normally you would not hard-code the password in source.  You should instead obtain it
'  from an interactive prompt, environment variable, or a secrets vault.
password = "mySshPassword"

success = tunnel.AuthenticatePw("mySshLogin",password)
If (success = 0) Then
    outFile.WriteLine(tunnel.LastErrorText)
    WScript.Quit
End If

'  Check whether the SSH transport is connected.  This is independent of the local listener
'  state -- the listener can still be accepting local connections even when this is 0,
'  though those connections would fail to forward.
If (tunnel.IsSshConnected()) Then
    outFile.WriteLine("The SSH transport is connected.")
Else
    outFile.WriteLine("The SSH transport is not connected.")
End If

waitForThreadExit = 1
success = tunnel.CloseTunnel(waitForThreadExit)
If (success = 0) Then
    outFile.WriteLine(tunnel.LastErrorText)
    WScript.Quit
End If


outFile.Close