VBScript

SSH Tunnel Authenticate with Password and Private Key

Demonstrates the Chilkat SshTunnel.AuthenticatePwPk method, which authenticates with a server that requires both a password and a private key. The arguments are the username, the password, and an SshKey private key.

Note: The private-key path is relative to the application's current working directory. Absolute paths may also be used. Supply the path to your own key file.

Background: Most servers require either a password or a public key, not both — but some high-security deployments mandate two-factor SSH. This method satisfies that policy in one call, combining something you know (the password) with something you have (the key). The password should come from a secure source rather than a literal.

Chilkat VBScript Downloads

Download Chilkat for VBScript

VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

'  Demonstrates the SshTunnel.AuthenticatePwPk method, which authenticates with an SSH server that
'  requires BOTH a password and a private key.  The 1st argument is the username, the 2nd is the
'  password, and the 3rd is an SshKey private key.

set tunnel = CreateObject("Chilkat.SshTunnel")

'  The tunnel forwards accepted local connections to this destination through the SSH server.
tunnel.DestHostname = "db.internal.example.com"
tunnel.DestPort = 5432

'  Connect to the SSH server.  This performs the TCP/proxy connection and SSH handshake, but
'  does not authenticate yet.
sshPort = 22
success = tunnel.Connect("ssh.example.com",sshPort)
If (success = 0) Then
    outFile.WriteLine(tunnel.LastErrorText)
    WScript.Quit
End If

'  Normally you would not hard-code the password in source.  You should instead obtain it
'  from an interactive prompt, environment variable, or a secrets vault.
password = "mySshPassword"

'  Load the SSH private key.  LoadText reads the file's text, which is then imported.
set privKey = CreateObject("Chilkat.SshKey")
keyText = privKey.LoadText("qa_data/id_rsa")
If (privKey.LastMethodSuccess = 0) Then
    outFile.WriteLine(privKey.LastErrorText)
    WScript.Quit
End If

success = privKey.FromOpenSshPrivateKey(keyText)
If (success = 0) Then
    outFile.WriteLine(privKey.LastErrorText)
    WScript.Quit
End If

success = tunnel.AuthenticatePwPk("mySshLogin",password,privKey)
If (success = 0) Then
    outFile.WriteLine(tunnel.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine("Authenticated with a password and a private key.")

'  After authenticating, call BeginAccepting to start listening for local connections to forward.

waitForThreadExit = 1
success = tunnel.CloseTunnel(waitForThreadExit)
If (success = 0) Then
    outFile.WriteLine(tunnel.LastErrorText)
    WScript.Quit
End If


outFile.Close