VBScript

Request an SSH Subsystem

Demonstrates the Chilkat Ssh.SendReqSubsystem method, which requests a predefined subsystem on a session channel. The first argument is the channel number and the second is the subsystem name. This example requests the sftp subsystem.

Background: A subsystem is a named service the server exposes over a channel instead of a shell command — sftp is the familiar example, and netconf is common on network devices. After acceptance, the channel carries that protocol's data, exchanged with the ordinary channel send and receive methods. If the server rejects the subsystem, the channel normally stays open and can be reused for another request.

Chilkat VBScript Downloads

Download Chilkat for VBScript

VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

'  Demonstrates the Ssh.SendReqSubsystem method, which requests a predefined subsystem on a
'  session channel.  The 1st argument is the channel number and the 2nd is the subsystem name.

set ssh = CreateObject("Chilkat.Ssh")

sshPort = 22
success = ssh.Connect("ssh.example.com",sshPort)
If (success = 0) Then
    outFile.WriteLine(ssh.LastErrorText)
    WScript.Quit
End If

'  Normally you would not hard-code the password in source.  You should instead obtain it
'  from an interactive prompt, environment variable, or a secrets vault.
password = "mySshPassword"

success = ssh.AuthenticatePw("mySshLogin",password)
If (success = 0) Then
    outFile.WriteLine(ssh.LastErrorText)
    WScript.Quit
End If

'  Open a session channel.  A negative return value indicates failure.
channelNum = ssh.OpenSessionChannel()
If (channelNum < 0) Then
    outFile.WriteLine(ssh.LastErrorText)
    WScript.Quit
End If

'  Request the "sftp" subsystem.  A 1 return means the server accepted the request;
'  subsequent protocol data is exchanged with the normal channel send and receive methods.
success = ssh.SendReqSubsystem(channelNum,"sftp")
If (success = 0) Then
    outFile.WriteLine(ssh.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine("Subsystem request accepted.")

ssh.Disconnect 

outFile.Close