VBScript

Open a direct-tcpip Channel (SSH Port Forwarding)

Demonstrates the Chilkat Ssh.OpenDirectTcpIpChannel method, which opens a direct-tcpip channel through the SSH server to a target host and port. The first argument is the target hostname and the second is the target port. It returns the channel number, or -1 on failure.

Background: This is SSH local port forwarding at the API level: the channel carries ordinary TCP traffic to a service that may be reachable only from the SSH server's network — a database, an internal web app, a message broker. The key detail is that the server resolves the target name, not your machine, so it must resolve and be reachable there. Supplying a numeric IPv4 address avoids remote DNS resolution entirely.

Chilkat VBScript Downloads

Download Chilkat for VBScript

VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

'  Demonstrates the Ssh.OpenDirectTcpIpChannel method, which opens a direct-tcpip channel
'  through the SSH server to a target host and port.  The 1st argument is the target hostname
'  and the 2nd is the target port.  It returns the channel number, or -1 on failure.

set ssh = CreateObject("Chilkat.Ssh")

sshPort = 22
success = ssh.Connect("ssh.example.com",sshPort)
If (success = 0) Then
    outFile.WriteLine(ssh.LastErrorText)
    WScript.Quit
End If

'  Normally you would not hard-code the password in source.  You should instead obtain it
'  from an interactive prompt, environment variable, or a secrets vault.
password = "mySshPassword"

success = ssh.AuthenticatePw("mySshLogin",password)
If (success = 0) Then
    outFile.WriteLine(ssh.LastErrorText)
    WScript.Quit
End If

'  The target name is resolved by the SSH server, not by this computer, so it must be
'  reachable from the server's network.
targetHostname = "db.internal.example.com"
targetPort = 5432
channelNum = ssh.OpenDirectTcpIpChannel(targetHostname,targetPort)
If (channelNum < 0) Then
    outFile.WriteLine(ssh.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine("Opened direct-tcpip channel: " & channelNum)

'  The channel now carries ordinary TCP data to the target, tunneled over SSH.

ssh.Disconnect 

outFile.Close