VBScript

Check Whether an SSH Exit Status Was Received

Demonstrates the Chilkat Ssh.ChannelReceivedExitStatus method, which reports whether the server supplied an exit-status value for a channel. The only argument is the channel number. When it returns true, call GetChannelExitStatus to read the value.

Background: Always test this before reading the exit status, because the server is not required to send one for every channel type or command — treating a missing status as "0" would silently turn a failure into a success. Exit status is independent of EOF and CLOSE: it can arrive after EOF and either before or together with CLOSE.

Chilkat VBScript Downloads

Download Chilkat for VBScript

VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

'  Demonstrates the Ssh.ChannelReceivedExitStatus method, which reports whether the server
'  supplied an exit-status value for a channel.  The only argument is the channel number.  When
'  it returns 1, call GetChannelExitStatus to read the value.

set ssh = CreateObject("Chilkat.Ssh")

sshPort = 22
success = ssh.Connect("ssh.example.com",sshPort)
If (success = 0) Then
    outFile.WriteLine(ssh.LastErrorText)
    WScript.Quit
End If

'  Normally you would not hard-code the password in source.  You should instead obtain it
'  from an interactive prompt, environment variable, or a secrets vault.
password = "mySshPassword"

success = ssh.AuthenticatePw("mySshLogin",password)
If (success = 0) Then
    outFile.WriteLine(ssh.LastErrorText)
    WScript.Quit
End If

channelNum = ssh.OpenSessionChannel()
If (channelNum < 0) Then
    outFile.WriteLine(ssh.LastErrorText)
    WScript.Quit
End If

success = ssh.SendReqExec(channelNum,"test -f /etc/hosts")
If (success = 0) Then
    outFile.WriteLine(ssh.LastErrorText)
    WScript.Quit
End If

'  IMPORTANT: Set a read timeout.  ReadTimeoutMs defaults to 0, which means no limit -- without
'  it, this call waits forever if the server never sends channel close.
ssh.ReadTimeoutMs = 15000

success = ssh.ChannelReceiveToClose(channelNum)
If (success = 0) Then
    outFile.WriteLine(ssh.LastErrorText)
    WScript.Quit
End If

'  The server is not required to send an exit status for every channel type or command.
If (ssh.ChannelReceivedExitStatus(channelNum)) Then
    exitStatus = ssh.GetChannelExitStatus(channelNum)
    outFile.WriteLine("Exit status: " & exitStatus)
Else
    outFile.WriteLine("The server did not provide an exit status.")
End If

ssh.Disconnect 

outFile.Close