VBScript

Check Whether SSH Channel CLOSE Was Received

Demonstrates the Chilkat Ssh.ChannelReceivedClose method, which reports whether an SSH CLOSE message has been received for a channel. The only argument is the channel number. Remote CLOSE is distinct from EOF and closes the channel in both directions.

Background: Remote CLOSE is the definitive end of a channel's life. Once it is processed, ChannelIsOpen becomes false and the channel is normally removed from NumOpenChannels. Checking it distinguishes "the server finished sending output" (EOF) from "the channel is fully finished" (CLOSE) — which is what you want before concluding a remote command has completely wrapped up.

Chilkat VBScript Downloads

Download Chilkat for VBScript

VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

'  Demonstrates the Ssh.ChannelReceivedClose method, which reports whether an SSH CLOSE message
'  has been received for a channel.  The only argument is the channel number.  Remote CLOSE is
'  distinct from EOF and closes the channel in both directions.

set ssh = CreateObject("Chilkat.Ssh")

sshPort = 22
success = ssh.Connect("ssh.example.com",sshPort)
If (success = 0) Then
    outFile.WriteLine(ssh.LastErrorText)
    WScript.Quit
End If

'  Normally you would not hard-code the password in source.  You should instead obtain it
'  from an interactive prompt, environment variable, or a secrets vault.
password = "mySshPassword"

success = ssh.AuthenticatePw("mySshLogin",password)
If (success = 0) Then
    outFile.WriteLine(ssh.LastErrorText)
    WScript.Quit
End If

channelNum = ssh.OpenSessionChannel()
If (channelNum < 0) Then
    outFile.WriteLine(ssh.LastErrorText)
    WScript.Quit
End If

success = ssh.SendReqExec(channelNum,"ls -l /tmp")
If (success = 0) Then
    outFile.WriteLine(ssh.LastErrorText)
    WScript.Quit
End If

'  IMPORTANT: Set a read timeout.  ReadTimeoutMs defaults to 0, which means no limit -- without
'  it, this call waits forever if the server never sends channel close.
ssh.ReadTimeoutMs = 15000

success = ssh.ChannelReceiveToClose(channelNum)
If (success = 0) Then
    outFile.WriteLine(ssh.LastErrorText)
    WScript.Quit
End If

'  The server may send EOF before CLOSE.  During that interval EOF is 1 while CLOSE is
'  still 0.
If (ssh.ChannelReceivedEof(channelNum)) Then
    outFile.WriteLine("EOF received.")
End If

If (ssh.ChannelReceivedClose(channelNum)) Then
    outFile.WriteLine("Remote CLOSE received -- the channel is closed in both directions.")
Else
    outFile.WriteLine("No remote CLOSE received.")
End If

ssh.Disconnect 

outFile.Close