VBScript

Receive an SSH Channel Until Close

Demonstrates the Chilkat Ssh.ChannelReceiveToClose method, which receives data on a channel until the server sends and Chilkat processes channel CLOSE. The only argument is the channel number. EOF alone does not complete this method.

Important: Set the ReadTimeoutMs property before calling this method. It defaults to 0, meaning no limit, so without it the call waits forever if the server never sends channel close.

Background: This is the simplest and most reliable way to collect the complete output of a one-shot exec command, because the server closes the channel when the command finishes. It is not appropriate for an interactive shell, which never closes on its own — use the poll-based methods there instead. Both stdout and stderr are processed, merged or kept separate according to StderrToStdout.

Chilkat VBScript Downloads

Download Chilkat for VBScript

VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

'  Demonstrates the Ssh.ChannelReceiveToClose method, which receives data on a channel until the
'  server sends channel CLOSE.  The only argument is the channel number.  EOF alone does not
'  complete this method.

set ssh = CreateObject("Chilkat.Ssh")

sshPort = 22
success = ssh.Connect("ssh.example.com",sshPort)
If (success = 0) Then
    outFile.WriteLine(ssh.LastErrorText)
    WScript.Quit
End If

'  Normally you would not hard-code the password in source.  You should instead obtain it
'  from an interactive prompt, environment variable, or a secrets vault.
password = "mySshPassword"

success = ssh.AuthenticatePw("mySshLogin",password)
If (success = 0) Then
    outFile.WriteLine(ssh.LastErrorText)
    WScript.Quit
End If

channelNum = ssh.OpenSessionChannel()
If (channelNum < 0) Then
    outFile.WriteLine(ssh.LastErrorText)
    WScript.Quit
End If

success = ssh.SendReqExec(channelNum,"ls -l /tmp")
If (success = 0) Then
    outFile.WriteLine(ssh.LastErrorText)
    WScript.Quit
End If

'  IMPORTANT: Set a read timeout.  ReadTimeoutMs defaults to 0, which means no limit -- without
'  it, this call waits forever if the server never sends channel close.
ssh.ReadTimeoutMs = 15000

'  Receive everything the command produces, up to and including channel close.
success = ssh.ChannelReceiveToClose(channelNum)
If (success = 0) Then
    outFile.WriteLine(ssh.LastErrorText)
    WScript.Quit
End If

output = ssh.GetReceivedText(channelNum,"utf-8")
If (ssh.LastMethodSuccess = 0) Then
    outFile.WriteLine(ssh.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine(output)

ssh.Disconnect 

outFile.Close