Read an SSH Channel with a Byte Threshold

See more SSH Examples

Demonstrates the Chilkat Ssh.ChannelReadAndPoll2 method, which works like ChannelReadAndPoll but also returns once newly processed data brings the total buffered data to or above a byte threshold. The arguments are the channel number, the poll timeout, and the threshold.

The integer return value is -1 on error, -2 if nothing arrived before the timeout, 0 if EOF or channel close was processed, or — when greater than 0 — the total bytes currently buffered for the channel (not the bytes newly received by this call).

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

'  Demonstrates the Ssh.ChannelReadAndPoll2 method, which works like ChannelReadAndPoll but also
'  returns once the total buffered data reaches or exceeds a byte threshold.  The 1st argument is
'  the channel number, the 2nd is the poll timeout, and the 3rd is the byte threshold.

set ssh = CreateObject("Chilkat.Ssh")

sshPort = 22
success = ssh.Connect("ssh.example.com",sshPort)
If (success = 0) Then
    outFile.WriteLine(ssh.LastErrorText)
    WScript.Quit
End If

'  Normally you would not hard-code the password in source.  You should instead obtain it
'  from an interactive prompt, environment variable, or a secrets vault.
password = "mySshPassword"

success = ssh.AuthenticatePw("mySshLogin",password)
If (success = 0) Then
    outFile.WriteLine(ssh.LastErrorText)
    WScript.Quit
End If

channelNum = ssh.OpenSessionChannel()
If (channelNum < 0) Then
    outFile.WriteLine(ssh.LastErrorText)
    WScript.Quit
End If

'  Start a shell WITHOUT requesting a PTY.  Without a PTY the shell sees it is connected to a
'  raw data pipe and enters non-interactive mode: it suppresses the command prompt, does not
'  echo typed commands back, and skips interactive login scripts.  The output is therefore
'  clean and easily parseable -- but because no prompt is ever sent, code must not wait for
'  one.  Instead, have each command print a predictable marker, or wait for EOF / channel close.
success = ssh.SendReqShell(channelNum)
If (success = 0) Then
    outFile.WriteLine(ssh.LastErrorText)
    WScript.Quit
End If

success = ssh.ChannelSendString(channelNum,"cat /var/log/syslog" & vbLf,"utf-8")
If (success = 0) Then
    outFile.WriteLine(ssh.LastErrorText)
    WScript.Quit
End If

'  Return when output goes quiet for 500ms, or once about 64KB has been buffered.  The
'  threshold is not a hard buffer limit -- a whole SSH packet may push the total above it.
pollTimeoutMs = 500
maxNumBytes = 65536
'  The return value is: -1 on error, -2 if nothing arrived before the timeout, 0 if EOF or
'  channel close was processed, or the total number of buffered bytes when greater than 0.
result = ssh.ChannelReadAndPoll2(channelNum,pollTimeoutMs,maxNumBytes)
If (result = -1) Then
    outFile.WriteLine(ssh.LastErrorText)
    WScript.Quit
End If

If (result = -2) Then
    outFile.WriteLine("No channel data arrived before the timeout.")
End If

If (result = 0) Then
    outFile.WriteLine("EOF or channel close was processed.  Buffered data may still remain.")
End If

If (result > 0) Then
    outFile.WriteLine("Total bytes buffered: " & result)
End If

output = ssh.GetReceivedText(channelNum,"utf-8")
If (ssh.LastMethodSuccess = 0) Then
    outFile.WriteLine(ssh.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine(output)

ssh.Disconnect 

outFile.Close