VBScript

SSH Authenticate with Password and Private Key

Demonstrates the Chilkat Ssh.AuthenticatePwPk method, which authenticates with a server that requires both a password and a private key. The first argument is the username, the second is the password, and the third is an SshKey private key.

Note: The private-key path is relative to the application's current working directory. Supply the path to your own key file.

Background: Most servers require either a password or a public key, not both — but some high-security configurations mandate multi-factor SSH, combining something you know (the password) with something you have (the key). This method satisfies that policy in one call. As always, the password should come from a secure source rather than a literal in code.

Chilkat VBScript Downloads

Download Chilkat for VBScript

VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

'  Demonstrates the Ssh.AuthenticatePwPk method, which authenticates with a server that requires
'  BOTH a password and a private key.  The 1st argument is the username, the 2nd is the
'  password, and the 3rd is an SshKey private key.

set ssh = CreateObject("Chilkat.Ssh")

'  Connect to the SSH server.  Port 22 is the usual SSH port.
sshPort = 22
success = ssh.Connect("ssh.example.com",sshPort)
If (success = 0) Then
    outFile.WriteLine(ssh.LastErrorText)
    WScript.Quit
End If

'  Normally you would not hard-code the password in source.  You should instead obtain it
'  from an interactive prompt, environment variable, or a secrets vault.
password = "mySshPassword"

'  Load the SSH private key.  LoadText reads the file's text, which is then imported.
set privKey = CreateObject("Chilkat.SshKey")
keyStr = privKey.LoadText("qa_data/id_rsa")
If (privKey.LastMethodSuccess = 0) Then
    outFile.WriteLine(privKey.LastErrorText)
    WScript.Quit
End If

success = privKey.FromOpenSshPrivateKey(keyStr)
If (success = 0) Then
    outFile.WriteLine(privKey.LastErrorText)
    WScript.Quit
End If

success = ssh.AuthenticatePwPk("mySshLogin",password,privKey)
If (success = 0) Then
    outFile.WriteLine(ssh.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine("Authenticated with password and private key.")

ssh.Disconnect 

outFile.Close