VBScript

SSH Authenticate with a Private Key

Demonstrates the Chilkat Ssh.AuthenticatePk method, which authenticates a connected SSH session using public-key authentication. The first argument is the username and the second is an SshKey private key. The matching public key must already be authorized for the account on the server.

Note: The private-key path is relative to the application's current working directory. Supply the path to your own key file.

Background: Public-key authentication is the standard for unattended and automated SSH: the private key stays on the client, the server trusts the corresponding public key, and no reusable password crosses the wire. The SshKey object imports keys in several formats — this example loads an OpenSSH private key. An empty or public-only key is rejected locally.

Chilkat VBScript Downloads

Download Chilkat for VBScript

VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

'  Demonstrates the Ssh.AuthenticatePk method, which authenticates a connected SSH session using
'  public-key authentication.  The 1st argument is the username and the 2nd is an SshKey private
'  key.  The matching public key must already be authorized for the account on the server.

set ssh = CreateObject("Chilkat.Ssh")

'  Connect to the SSH server.  Port 22 is the usual SSH port.
sshPort = 22
success = ssh.Connect("ssh.example.com",sshPort)
If (success = 0) Then
    outFile.WriteLine(ssh.LastErrorText)
    WScript.Quit
End If

'  Load the SSH private key.  LoadText reads the file's text, which is then imported.
set privKey = CreateObject("Chilkat.SshKey")
keyStr = privKey.LoadText("qa_data/id_rsa")
If (privKey.LastMethodSuccess = 0) Then
    outFile.WriteLine(privKey.LastErrorText)
    WScript.Quit
End If

success = privKey.FromOpenSshPrivateKey(keyStr)
If (success = 0) Then
    outFile.WriteLine(privKey.LastErrorText)
    WScript.Quit
End If

success = ssh.AuthenticatePk("mySshLogin",privKey)
If (success = 0) Then
    outFile.WriteLine(ssh.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine("Authenticated with private key.")

ssh.Disconnect 

outFile.Close