VBScript

Receive a String from a Socket

Demonstrates Socket.ReceiveString, which receives text and decodes it using StringCharset. It returns the first nonempty decoded result rather than draining all available data.

Background. Text send and receive operations encode and decode bytes using the StringCharset property. For plain ASCII or UTF-8 protocols, setting StringCharset to utf-8 is a safe default.

Chilkat VBScript Downloads

Download Chilkat for VBScript

VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

set socket = CreateObject("Chilkat.Socket")

'  Connect to the server using TLS.  The 3rd argument enables the TLS handshake after the TCP
'  connection succeeds; the 4th is the maximum time to wait, in milliseconds.
bTls = 1
maxWaitMs = 5000
success = socket.Connect("example.com",5000,bTls,maxWaitMs)
If (success = 0) Then
    outFile.WriteLine(socket.LastErrorText)
    WScript.Quit
End If

'  StringCharset controls the character encoding used when sending and receiving text.
socket.StringCharset = "utf-8"
'  Send a request using a simple application-defined text protocol in which each message ends with a
'  CRLF.
command = "STATUS" & vbCrLf
success = socket.SendString(command)
If (success = 0) Then
    outFile.WriteLine(socket.LastErrorText)
    WScript.Quit
End If

'  Receive text and decode it using StringCharset.  ReceiveString returns the first nonempty decoded
'  result; it does not keep reading to drain all available data.
responseText = socket.ReceiveString()
If (socket.LastMethodSuccess = 0) Then
    outFile.WriteLine(socket.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine(responseText)

outFile.Close