Receive Text from a Socket into a StringBuilder

See more Socket/SSL/TLS Examples

Demonstrates Socket.ReceiveSb, which receives text, decodes it using StringCharset, and appends it to a StringBuilder.

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

set socket = CreateObject("Chilkat.Socket")

'  Connect to the server using TLS.  The 3rd argument enables the TLS handshake after the TCP
'  connection succeeds; the 4th is the maximum time to wait, in milliseconds.
bTls = 1
maxWaitMs = 5000
success = socket.Connect("example.com",5000,bTls,maxWaitMs)
If (success = 0) Then
    outFile.WriteLine(socket.LastErrorText)
    WScript.Quit
End If

'  StringCharset controls the character encoding used when sending and receiving text.
socket.StringCharset = "utf-8"
'  Send a request using a simple application-defined text protocol in which each message ends with a
'  CRLF.
command = "STATUS" & vbCrLf
success = socket.SendString(command)
If (success = 0) Then
    outFile.WriteLine(socket.LastErrorText)
    WScript.Quit
End If

'  Receive text and append it to a StringBuilder, decoding using StringCharset.
set sb = CreateObject("Chilkat.StringBuilder")
success = socket.ReceiveSb(sb)
If (success = 0) Then
    outFile.WriteLine(socket.LastErrorText)
    WScript.Quit
End If

responseText = sb.GetAsString()
If (sb.LastMethodSuccess = 0) Then
    outFile.WriteLine(sb.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine(responseText)

outFile.Close