VBScript

SOAP Web Service (HTTP POST)

Demonstrates how to call PostXml to call a SOAP web service. VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' --------------------------------------------------------------------------------
' Also see Chilkat's Online WSDL Code Generator
' to generate code and SOAP Request and Response XML for each operation in a WSDL.
' --------------------------------------------------------------------------------

' This example uses a live web service at:
' http://www.webservicex.net/uklocation.asmx
' It gets the UK town,Postcode and County by Postcode(First Section of Post Code)

' The SOAP XML will look like this:
' <?xml version="1.0" encoding="utf-8"?>
' <soap:Envelope xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" xmlns:xsd="http://www.w3.org/2001/XMLSchema" xmlns:soap="http://schemas.xmlsoap.org/soap/envelope/">
'   <soap:Body>
'     <GetUKLocationByPostCode xmlns="http://www.webserviceX.NET">
'       <PostCode>string</PostCode>
'     </GetUKLocationByPostCode>
'   </soap:Body>
' </soap:Envelope>

' For this example's sake, we'll load the XML from a file.  We'll test using PostCode "E3".  
' The SOAP XML for this example may be downloaded from:
' http://www.chilkatsoft.com/testData/ukPostCodeSoap.xml
set xml = CreateObject("Chilkat.Xml")
success = xml.LoadXmlFile("ukPostCodeSoap.xml")
If (success = 0) Then
    outFile.WriteLine(xml.LastErrorText)
    WScript.Quit
End If

strXml = xml.GetXml()

set http = CreateObject("Chilkat.Http")

' We'll need to add this in the HTTP header:
' SOAPAction: "http://www.webserviceX.NET/GetUKLocationByPostCode"
http.SetRequestHeader "SOAPAction","http://www.webserviceX.NET/GetUKLocationByPostCode"

' The endpoint for this soap service is:
endPoint = "http://www.webservicex.net/uklocation.asmx"

' Note: This particular web service was live and functioning at the time this example
' was written.  It is possible that as time progresses, this web service will no longer
' be availble...
set resp = CreateObject("Chilkat.HttpResponse")
success = http.HttpStr("POST",endPoint,strXml,"utf-8","text/xml",resp)
If (success = 0) Then
    outFile.WriteLine(http.LastErrorText)
    WScript.Quit
End If

responseStatusCode = resp.StatusCode
' You may wish to verify that the responseStatusCode equals 200...
outFile.WriteLine("Response Status Code: " & responseStatusCode)

' You may examine the exact HTTP header sent with the POST like this:
outFile.WriteLine("LastHeader:")
outFile.WriteLine(http.LastHeader)

' Examine the XML returned by the web service:
outFile.WriteLine("XML Response:")
set xmlResp = CreateObject("Chilkat.Xml")
success = xmlResp.LoadXml(resp.BodyStr)
outFile.WriteLine(xmlResp.GetXml())

' Use this online tool to generate parsing code from response XML: 
' Generate Parsing Code from XML

outFile.Close