(VBScript) SMTP Inspection

See more SMTP Examples

Examine an SMTP session to view all communications sent to the SMTP server.

Chilkat ActiveX Downloads

ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

set mailman = CreateObject("Chilkat.MailMan")

mailman.SmtpHost = "smtp.example.com"
mailman.SmtpUsername = "myUsername"
mailman.SmtpPassword = "myPassword"

mailman.SmtpPort = 465
mailman.StartTLS = 1

set email = CreateObject("Chilkat.Email")

email.Subject = "This is a test"
email.Body = "This is a test"
email.From = "Alex <alex@example.com>"
success = email.AddTo("Christoph","christoph@example2.com")
success = email.AddBcc("Victor","victor@example3.com")

' Generate the MIME that is sent when SendEmail is called
mimeStr = mailman.RenderToMime(email)
outFile.WriteLine(mimeStr)

success = mailman.SendEmail(email)
If (success = 0) Then
    outFile.WriteLine(mailman.LastErrorText)
    WScript.Quit
End If

success = mailman.CloseSmtpConnection()
If (success <> 1) Then
    outFile.WriteLine("Connection to SMTP server not closed cleanly.")
End If

' Examine the SMTP session log.
outFile.WriteLine("----")
outFile.WriteLine("Smtp Session Log:")
outFile.WriteLine(mailman.SmtpSessionLog)

' ---------------------------------------------------
' Sample output:
' ---------------------------------------------------

' MIME-Version: 1.0
' Date: Fri, 06 Mar 2026 16:21:00 -0600
' Message-ID: <A5DC25990C93EC2676F4FBB2BB3BFA9EB34FF9D3@CHILKAT25>
' Content-Type: text/plain; charset=us-ascii; format=flowed
' Content-Transfer-Encoding: 7bit
' X-Priority: 3 (Normal)
' Subject: This is a test
' From: Alex <alex@example.com>
' To: Christoph <christoph@example2.com>
' Bcc: Victor <victor@example3.com>
' 
' This is a test
' ----
' Smtp Session Log:
' 220 smtp.example.com ESMTP Amazon WorkMail SMTP Service
' EHLO MYCOMPUTER<CRLF>
' 250-smtp.example.com
' 250-8BITMIME
' 250-AUTH PLAIN LOGIN
' 250 Ok
' AUTH LOGIN<CRLF>
' 334 VXNlcm5hbWU6
' YWRtaW5AY2hpbGthdHNvZnQuY29t<CRLF>
' 334 UGFzc3dvcmQ6
' {PasswordOrCredentials}
' 235 Authentication successful.
' MAIL FROM:<alex@example.com><CRLF>
' 250 Ok
' RCPT TO:<christoph@example2.com><CRLF>
' 250 Ok
' RCPT TO:<victor@example3.com><CRLF>
' 250 Ok
' DATA<CRLF>
' 354 End data with <CR><LF>.<CR><LF>
' {388 bytes} <--- The MIME source of the email (examined via RenderToMime) was sent here.
' <CRLF>.<CRLF>
' 250 Ok
' QUIT<CRLF>
' 221 Bye

outFile.Close