VBScript

SFTP Authenticate Secure

Demonstrates how to do SFTP password authentication with secure strings.

This example requires Chilkat v9.5.0.71 or greater.

VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' Imagine we've previously saved our encrypted login and password within a JSON config file
' that contains this:

' {
'   "ssh_login": "2+qylFfC56Ck7OQQt/U2/w==",
'   "ssh_password": "5neIq9Jmn0E3p71N6Yc8TA=="
' }

set json = CreateObject("Chilkat.JsonObject")
success = json.LoadFile("qa_data/passwords/ssh.json")

set crypt = CreateObject("Chilkat.Crypt2")

' These are the encryption settings we previously used to encrypt the credentials within the JSON config file.
crypt.CryptAlgorithm = "aes"
crypt.CipherMode = "cbc"
crypt.KeyLength = 128
crypt.SetEncodedKey "000102030405060708090A0B0C0D0E0F","hex"
crypt.SetEncodedIV "000102030405060708090A0B0C0D0E0F","hex"
crypt.EncodingMode = "base64"

set ssLogin = CreateObject("Chilkat.SecureString")
set ssPassword = CreateObject("Chilkat.SecureString")

' Decrypt to the secure string.  (the strings will still held in memory encrypted, but are now encrypted using
' a randomly generated session key.)
success = crypt.DecryptSecureENC(json.StringOf("ssh_login"),ssLogin)
success = crypt.DecryptSecureENC(json.StringOf("ssh_password"),ssPassword)

set sftp = CreateObject("Chilkat.SFtp")

success = sftp.Connect("MY-SSH-SERVER-DOMAIN-OR-IP",22)
If (success <> 1) Then
    outFile.WriteLine(sftp.LastErrorText)
    WScript.Quit
End If

' Authenticate using secure strings
success = sftp.AuthenticateSecPw(ssLogin,ssPassword)
If (success <> 1) Then
    outFile.WriteLine(sftp.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine("SFTP Authentication successful.")

sftp.Disconnect 

outFile.Close