VBScript

SCP Download Files Matching a Pattern, such as *.txt

See more SCP Examples

Demonstrates how to SCP download files matching a pattern, such as *.txt. VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

set ssh = CreateObject("Chilkat.Ssh")

' Connect to an SSH server:
hostname = "MY-SSH-SERVER-DOMAIN-OR-IP"
port = 22

success = ssh.Connect(hostname,port)
If (success <> 1) Then
    outFile.WriteLine(ssh.LastErrorText)
    WScript.Quit
End If

' Wait a max of 5 seconds when reading responses..
ssh.IdleTimeoutMs = 5000

' Authenticate using login/password:
success = ssh.AuthenticatePw("MY-SSH-LOGIN","MY-SSH-PASSWORD")
If (success <> 1) Then
    outFile.WriteLine(ssh.LastErrorText)
    WScript.Quit
End If

' Once the SSH object is connected and authenticated, use it
' in the SCP object.
set scp = CreateObject("Chilkat.Scp")

success = scp.UseSsh(ssh)
If (success <> 1) Then
    outFile.WriteLine(scp.LastErrorText)
    WScript.Quit
End If

scp.HeartbeatMs = 200

' Set the SyncMustMatch property to "*.pem" to download only .pem files
scp.SyncMustMatch = "*.pem"

remoteDir = "qa_syncA"
localDir = "c:/aaworkarea/scp/qa_syncA"

' Download synchronization modes:
' mode=0: Download all files
' mode=1: Download all files that do not exist on the local filesystem.
' mode=2: Download newer or non-existant files.
' mode=3: Download only newer files.  
'         If a file does not already exist on the local filesystem, it is not downloaded from the server.
' mode=5: Download only missing files or files with size differences.
' mode=6: Same as mode 5, but also download newer files.
mode = 0

' Do not recurse the remote directory tree.  Only download files matching *.pem
' from the given remote directory.
bRecurse = 0

success = scp.SyncTreeDownload(remoteDir,localDir,mode,bRecurse)
If (success <> 1) Then
    outFile.WriteLine(scp.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine("SCP download matching success.")

' Disconnect
ssh.Disconnect 

outFile.Close