VBScript

S3 Find Bucket Region

See more Amazon S3 (new) Examples

Demonstrates how to find out the region of an S3 bucket. VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' This requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

set rest = CreateObject("Chilkat.Rest")

' Connect to the Amazon AWS REST server using the correct region (in this example, "us-west-2")
bTls = 1
port = 443
bAutoReconnect = 1
success = rest.Connect("s3.amazonaws.com",port,bTls,bAutoReconnect)

' Provide AWS credentials for the REST call.
set authAws = CreateObject("Chilkat.AuthAws")
authAws.AccessKey = "AWS_ACCESS_KEY"
authAws.SecretKey = "AWS_SECRET_KEY"
authAws.ServiceName = "s3"
success = rest.SetAuthAws(authAws)

' The bucket name we want to know about is set in the HOST header.
' In this example, we want to find the region for the "chilkat.qa" bucket.
rest.Host = "chilkat.qa.s3.amazonaws.com"

' Send the GET request to query the bucket location.
strResult = rest.FullRequestNoBody("GET","/?location")
If (rest.LastMethodSuccess <> 1) Then
    outFile.WriteLine(rest.LastErrorText)
    WScript.Quit
End If

responseStatusCode = rest.ResponseStatusCode
outFile.WriteLine("Response status code = " & responseStatusCode)
If (responseStatusCode <> 200) Then
    outFile.WriteLine(rest.ResponseHeader)
    outFile.WriteLine(strResult)
    outFile.WriteLine("Failed.")
    WScript.Quit
End If

outFile.WriteLine(strResult)

' The result contains XML like this:
' <?xml version="1.0" encoding="UTF-8"?>
' <LocationConstraint xmlns="http://s3.amazonaws.com/doc/2006-03-01/">us-west-2</LocationConstraint>

' Get the "us-west-2" from the XML
set xml = CreateObject("Chilkat.Xml")
success = xml.LoadXml(strResult)
outFile.WriteLine("region = " & xml.Content)

outFile.Close