VBScript

Create S3 Bucket in a Region

See more Amazon S3 Examples

Demonstrates how to create an S3 bucket in a specified region. This example will create a bucket in the eu-west-2 region. VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

set rest = CreateObject("Chilkat.Rest")

' Connect to the Amazon AWS REST server.
bTls = 1
port = 443
bAutoReconnect = 1
success = rest.Connect("s3.amazonaws.com",port,bTls,bAutoReconnect)

' Provide AWS credentials for the REST call.
set authAws = CreateObject("Chilkat.AuthAws")
authAws.AccessKey = "AWS_ACCESS_KEY"
authAws.SecretKey = "AWS_SECRET_KEY"
authAws.ServiceName = "s3"
success = rest.SetAuthAws(authAws)

' We'll send a PUT request having an XML body such as this:
' <CreateBucketConfiguration xmlns="http://s3.amazonaws.com/doc/2006-03-01/"> 
'   <LocationConstraint>BucketRegion</LocationConstraint> 
'   </CreateBucketConfiguration>

' Create the XML body specifying the region as "eu-west-2"
bucketRegion = "eu-west-2"
set sbBucketRegion = CreateObject("Chilkat.StringBuilder")
success = sbBucketRegion.Append(bucketRegion)

' We only need to specify the LocationConstraint if the bucket's region is NOT us-east-1
set xml = CreateObject("Chilkat.Xml")
If (Not sbBucketRegion.ContentsEqual("us-east-1")) Then
    xml.Tag = "CreateBucketConfiguration"
    success = xml.AddAttribute("xmlns","http://s3.amazonaws.com/doc/2006-03-01/")
    xml.UpdateChildContent "LocationConstraint","eu-west-2"
End If

' --------------------------------------------------------------
' IMPORTANT: To create a bucket in the default us-east-1 region,
' do not add the LocationConstraint.  Adding a LocationConstraint of "us-east-1"
' causes an error "The specified location-constraint is not valid."
' By default, the bucket is created in us-east-1 by sending a PUT with an empty body.
' --------------------------------------------------------------

' Set the bucket name via the HOST header.
' In this case, the bucket name is "chilkateuwest2".
rest.Host = "chilkateuwest2.s3.amazonaws.com"

' Make the call to create the bucket.

If (Not sbBucketRegion.ContentsEqual("us-east-1")) Then
    responseStr = rest.FullRequestString("PUT","/",xml.GetXml())
Else
    ' If the bucket is to be created in the us-east-1 region (the default region)
    ' just send a PUT with no body.
    responseStr = rest.FullRequestNoBody("PUT","/")
End If

If (rest.LastMethodSuccess <> 1) Then
    outFile.WriteLine(rest.LastErrorText)
    WScript.Quit
End If

If (rest.ResponseStatusCode <> 200) Then
    outFile.WriteLine("status code = " & rest.ResponseStatusCode)
    set responseXml = CreateObject("Chilkat.Xml")
    success = responseXml.LoadXml(responseStr)
    outFile.WriteLine(responseXml.GetXml())
    outFile.WriteLine("Failed.")
    WScript.Quit
End If

outFile.WriteLine("Bucket in the eu-west-2 region created.")

outFile.Close