(VBScript) Verify an RSA Signature Against the Signed Hash

See more Apple Keychain Examples

Demonstrates how to validate an RSA Signature against the hash that was signed.

Note: This example requires Chilkat v11.0.0 or greater.

Chilkat ActiveX Downloads

ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

set bd = CreateObject("Chilkat.BinData")

For i = 0 To 100
    success = bd.AppendEncoded("000102030405060708090A0B0C0D0E0F","hex")
Next
sha256_base64 = bd.GetHash("sha256","base64")
outFile.WriteLine("sha256 hash in base64 format: " & sha256_base64)

base64_rsa_sig = "AwF2BbOvL6jA5DwmMAc9n6J2Cc8PI6Rj5W079+aKJcIEtPWRzHor0Bvc3aftGM3Jbgj6SXlIC3M3RYS7UZOnfiHKFNZgbxaNT5WwsWooK42ZkC8DBZl0p7OunBUKd5SciUo+TKilioeUkriN3L1Zl9hwi3HVDVqgVo3XXskwIftSqLSFlepTLTmOWj9Y93dp8J4D9RyLtNgFQBc0WB22tyJTsuY56mLcWe1AMF3LizB9OrbwjynF2u16xWlrJdugccz795fJBUV9aQSD+8S3KeqwQhoi8RK1uhD68aGCyaSpBq0NZ8COAkn7MXaF4POxrAAt8udfHM+PRfSOptcH/w=="

' Get the public key to be used for signature verification.
set pubKey = CreateObject("Chilkat.PublicKey")
success = pubKey.LoadFromFile("rsaKeys/chilkat-rsa-2048.pem")
If (success = 0) Then
    outFile.WriteLine(pubKey.LastErrorText)
    WScript.Quit
End If

set rsa = CreateObject("Chilkat.Rsa")
success = rsa.UsePublicKey(pubKey)
If (success = 0) Then
    outFile.WriteLine(rsa.LastErrorText)
    WScript.Quit
End If

' Verify the hash against the signature.
rsa.EncodingMode = "base64"
success = rsa.VerifyHashENC(sha256_base64,"sha256",base64_rsa_sig)

If (success = 0) Then
    outFile.WriteLine(rsa.LastErrorText)
    outFile.WriteLine("Signature invalid.")
Else
    outFile.WriteLine("Signature valid.")
End If


outFile.Close