Chilkat Examples

ChilkatHOMEAndroid™Classic ASPCC++C#Mono C#.NET Core C#C# UWP/WinRTDataFlexDelphi ActiveXDelphi DLLVisual FoxProJavaLianjaMFCObjective-CPerlPHP ActiveXPHP ExtensionPowerBuilderPowerShellPureBasicCkPythonChilkat2-PythonRubySQL ServerSwift 2Swift 3/4TclUnicode CUnicode C++Visual Basic 6.0VB.NETVB.NET UWP/WinRTVBScriptXojo PluginNode.jsExcelGo

VBScript Examples

ASN.1
Amazon S3
Amazon S3 (new)
Amazon SES
Amazon SNS
Amazon SQS
Async
Azure Cloud Storage
Azure Service Bus
Base64
Bounced Email
Box
CSR
CSV
Certificates
Compression
DKIM / DomainKey
DSA
Diffie-Hellman
Digital Signatures
Dropbox
Dynamics CRM
ECC
Email Object
Encryption
FTP
Facebook
FileAccess
Firebase
GMail REST API
GeoOp
Google APIs
Google Calendar
Google Cloud Storage
Google Drive
Google Sheets
Gzip
HTML-to-XML/Text
HTTP
HTTP Misc
IMAP
JSON
JSON Web Encryption (JWE)
JSON Web Signatures (JWS)
JSON Web Token (JWT)

Java KeyStore (JKS)
Jira
MHT / HTML Email
MIME
Microsoft Graph
NTLM
OAuth1
OAuth2
OneDrive
OpenSSL
Outlook
PEM
PFX/P12
POP3
PRNG
PayPal
Peoplevox
QuickBooks
REST
REST Misc
RSA Encryption
SCP
SFTP
SMTP
SSH
SSH Key
SSH Tunnel
SharePoint
Shopify
Socket/SSL/TLS
Spider
Stream
Stripe
SugarCRM
Tar Archive
Twitter
Upload
VoiceBase
Walmart
WebSocket
XAdES
XML
XML Digital Signatures
XMP
Xero
Zip
curl
eBay

 

 

 

(VBScript) Duplicating OpenSSL rsautl (creating RSA signatures)

Demonstrates how to duplicate OpenSSL rsautil RSA signatures.

The Chilkat RSA component's methods for creating RSA signatures (SignBytes, SignBytesENC, SignString, and SignStringENC) are very different from OpenSSL's rsautl command. First, we'll explain what Chilkat's signing methods do, and then what OpenSSL's rsautl does. New signing methods have been added to Chilkat RSA to duplicate OpenSSL rsautl: OpenSslSignBytes, OpenSslSignBytesENC, OpenSslSignString, and OpenSslSignStringENC.

Here's what Chilkat's RSA Sign* methods do:
(Note: Chilkat RSA's Sign* methods generate signatures according to RSA Laboratories' "PKCS #1 v2.0: RSA Cryptography Standard".)

  1. Input data is hashed using the hashing algorithm specified.
  2. The hash is padded using either PKCS1 v1.5 or PKCS1 PSS padding. PKCS v1.5 involves encoding to ASN.1 before padding.
  3. The padded hash is finally RSA signed (i.e. modular exponentiation) and the signature is returned.

OpenSSL rsautl is very different. Here's what it does:

  1. The input data is not hashed. It must be a small enough amount of data such that it can be padded and signed. PKCS v1.5 padding is always used. The data is not ASN.1 encoded before padding.
  2. The PKCS v1.5 padded data is RSA signed and the signature is returned.
The new OpenSsl* methods are designed to duplicate OpenSSL's rsautil signature functionality.

Chilkat ActiveX Downloads

ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
Set outFile = fso.CreateTextFile("output.txt", True)



set pkey = CreateObject("Chilkat_9_5_0.PrivateKey")

'  Load the private key from an RSA PEM file:
success = pkey.LoadPemFile("private.pem")
If (success <> 1) Then
    outFile.WriteLine(pkey.LastErrorText)
    WScript.Quit
End If

'  Get the private key in XML format:
pkeyXml = pkey.GetXml()

set rsa = CreateObject("Chilkat_9_5_0.Rsa")

'  Any string argument automatically begins the 30-day trial.
success = rsa.UnlockComponent("30-day trial")
If (success <> 1) Then
    outFile.WriteLine("RSA component unlock failed")
    WScript.Quit
End If

'  Import the private key into the RSA component:
success = rsa.ImportPrivateKey(pkeyXml)
If (success <> 1) Then
    outFile.WriteLine(rsa.LastErrorText)
    WScript.Quit
End If

'  This example will sign a string, and receive the signature
'  in a hex-encoded string.  Therefore, set the encoding mode
'  to "hex":
rsa.EncodingMode = "hex"

strData = "secret"

'  Create an OpenSSL style signature:
hexSig = rsa.OpenSslSignStringENC(strData)

outFile.WriteLine(hexSig)

'  Recover the data using the corresponding public key:
set pubkey = CreateObject("Chilkat_9_5_0.PublicKey")

'  Load the public key from a PEM file:
success = pubkey.LoadOpenSslPemFile("public.pem")
If (success <> 1) Then
    outFile.WriteLine(pubkey.LastErrorText)
    WScript.Quit
End If

'  Get the public key in XML format:
pubkeyXml = pubkey.GetXml()

set rsa2 = CreateObject("Chilkat_9_5_0.Rsa")

'  Import the public key into the RSA component:
success = rsa2.ImportPublicKey(pubkeyXml)
If (success <> 1) Then
    outFile.WriteLine(rsa2.LastErrorText)
    WScript.Quit
End If

rsa2.EncodingMode = "hex"

'  Recover the original data.

originalData = rsa2.OpenSslVerifyStringENC(hexSig)

outFile.WriteLine(originalData)

outFile.Close

 

© 2000-2019 Chilkat Software, Inc. All Rights Reserved.