VBScript

RSA Hash Binary Data and Sign (and Verify)

See more RSA Examples

Demonstrates how to sign the hash of binary data. Also demonstrates how to verify the RSA signature. VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' Load an RSA private key for signing.
set privKey = CreateObject("Chilkat.PrivateKey")
success = privKey.LoadEncryptedPemFile("qa_data/pem/rsa_passwd.pem","passwd")
If (success = 0) Then
    outFile.WriteLine(privKey.LastErrorText)
    WScript.Quit
End If

set rsa = CreateObject("Chilkat.Rsa")
success = rsa.UsePrivateKey(privKey)

' We have some binary data (in hex) to sign
originalData = "0102030405060708090A"
set bdData = CreateObject("Chilkat.BinData")
success = bdData.AppendEncoded(originalData,"hex")

' Hash (SHA-256) and sign the hash:
set bdSignature = CreateObject("Chilkat.BinData")
success = rsa.SignBd(bdData,"sha256",bdSignature)
If (success = 0) Then
    outFile.WriteLine(rsa.LastErrorText)
    WScript.Quit
End If

' Show the RSA signature in base64
outFile.WriteLine(bdSignature.GetEncoded("base64"))

' ------------------------------------------
' Get the public key from the private key
set pubKey = CreateObject("Chilkat.PublicKey")
success = privKey.ToPublicKey(pubKey)

' Verify the signature..
set rsa2 = CreateObject("Chilkat.Rsa")
success = rsa2.UsePublicKey(pubKey)

bVerified = rsa2.VerifyBd(bdData,"sha256",bdSignature)
outFile.WriteLine("signature verified: " & bVerified)

outFile.Close