VBScript

Fetch S3 Object Metadata

See more Amazon S3 (new) Examples

Demonstrates how to get the metadata for an S3 object using the REST API.

The HEAD operation retrieves metadata from an object without returning the object itself. This operation is useful if you are interested only in an object's metadata. To use HEAD, you must have READ access to the object.

A HEAD request has the same options as a GET operation on an object. The response is identical to the GET response except that there is no response body.

VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

set rest = CreateObject("Chilkat.Rest")

' Connect to the Amazon AWS REST server using the correct region (in this example, "us-west-2")
bTls = 1
port = 443
bAutoReconnect = 1
success = rest.Connect("s3-us-west-2.amazonaws.com",port,bTls,bAutoReconnect)

' Provide AWS credentials for the REST call.
set authAws = CreateObject("Chilkat.AuthAws")
authAws.AccessKey = "AWS_ACCESS_KEY"
authAws.SecretKey = "AWS_SECRET_KEY"
authAws.ServiceName = "s3"
' Make sure the Region agrees with the region in the Connect.
authAws.Region = "us-west-2"
success = rest.SetAuthAws(authAws)

' User-defined metadata are name/value pairs, and are returned in the HTTP response header.
' Metadata header names begin with "x-amz-meta-" to distinguish them from other HTTP headers.
' Note that Amazon S3 stores user-defined metadata keys in lowercase.

' Set the bucket name via the HOST header.
' In this case, the bucket name is "chilkat.ocean".
rest.Host = "chilkat.ocean.s3.amazonaws.com"

' Send the HEAD request.
success = rest.SendReqNoBody("HEAD","/seahorse.jpg")
If (success <> 1) Then
    outFile.WriteLine(rest.LastErrorText)
    WScript.Quit
End If

' Read the response header.
responseStatusCode = rest.ReadResponseHeader()
If (responseStatusCode < 0) Then
    outFile.WriteLine(rest.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine("Response status code = " & responseStatusCode)
If (responseStatusCode <> 200) Then
    outFile.WriteLine(rest.ResponseHeader)
    outFile.WriteLine("Object does not exist.")
    WScript.Quit
End If

' Show the full response header that was received:
outFile.WriteLine("Response header:")
outFile.WriteLine(rest.ResponseHeader)
outFile.WriteLine("--")

' Here is an example response header:

' 	x-amz-id-2: uS4Flff04M8x5YWajU231TP0ClBL19mMhuyfU5ZVQd6NsUHXVhHK+H3b0sjxY98Fujet1ejhyzk=
' 	x-amz-request-id: 27950009AA8E68AA
' 	Date: Mon, 23 Jan 2017 20:12:58 GMT
' 	Last-Modified: Fri, 20 Jan 2017 00:22:57 GMT
' 	ETag: "a8551f0a5437f43a796fca7623ee9232"
' 	x-amz-meta-species: big-belly seahorse
' 	x-amz-meta-genus: Hippocampus
' 	x-amz-meta-habitat: shallow tropical and temperate waters
' 	Accept-Ranges: bytes
' 	Content-Type: image/jpg
' 	Content-Length: 24388
' 	Server: AmazonS3

' Examine particular response headers (the object metadata headers..)
outFile.WriteLine("x-amz-meta-species: " & rest.ResponseHdrByName("x-amz-meta-species"))
outFile.WriteLine("x-amz-meta-genus: " & rest.ResponseHdrByName("x-amz-meta-genus"))
outFile.WriteLine("x-amz-meta-habitat: " & rest.ResponseHdrByName("x-amz-meta-habitat"))
outFile.WriteLine("--")

' It is possible to iterate over the header fields to find all x-amz-meta* headers
i = 0
numHeaders = rest.NumResponseHeaders
set sbName = CreateObject("Chilkat.StringBuilder")
Do While i < numHeaders
    success = sbName.SetString(rest.ResponseHdrName(i))
    If (sbName.StartsWith("x-amz-meta",0) = 1) Then
        outFile.WriteLine(sbName.GetAsString() & ": " & rest.ResponseHdrValue(i))
    End If

    i = i + 1
Loop

' The output:

' 	x-amz-meta-species: big-belly seahorse
' 	x-amz-meta-genus: Hippocampus
' 	x-amz-meta-habitat: shallow tropical and temperate waters

outFile.Close