VBScript Requires Chilkat v11.1.0+

Delete All Email in a POP3 Mailbox

Delete all email in a POP3 mailbox. VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

'  This example assumes the Chilkat API to have been previously unlocked.
'  See Global Unlock Sample for sample code.

'  The mailman object is used for receiving (POP3) 
'  and sending (SMTP) email.
set mailman = CreateObject("Chilkat.MailMan")

'  Set the POP3 server's hostname
mailman.MailHost = "pop.example.com"

'  Set the POP3 login/password.
mailman.PopUsername = "bob@example.com"
mailman.PopPassword = "****"

'  Make sure the ImmediateDelete property is set (this is the default)
'  If ImmediateDelete is not set, messages marked for deletion
'  by the Delete* methods will not be deleted until the POP3
'  connection is closed by calling Pop3EndSession.
mailman.ImmediateDelete = 1

'  First, get all the UIDLs.
set stUidls = CreateObject("Chilkat.StringTable")
success = mailman.FetchUidls(stUidls)
If (success = 0) Then
    outFile.WriteLine(mailman.LastErrorText)
    WScript.Quit
End If

'  Next, delete them all.
success = mailman.DeleteUidlSet(stUidls)
If (success = 0) Then
    outFile.WriteLine(mailman.LastErrorText)
    WScript.Quit
End If

'  We're done with the POP3 session, so it doesn't hurt to call this...
success = mailman.Pop3EndSession()
If (success = 0) Then
    outFile.WriteLine(mailman.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine("Success.")

outFile.Close