VBScript

PKCS11 Find Certificate with Key Usage on Smart Card or USB Token

See more PKCS11 Examples

Demonstrates how to find and return the 1st certificate on a smart card or USB token with a desired intended key usage.

Note: This example requires Chilkat v9.5.0.91 or later.

VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' Note: Chilkat's PKCS11 implementation runs on Windows, Linux, Mac OS X, and other supported operating systems.

set pkcs11 = CreateObject("Chilkat.Pkcs11")

pkcs11.SharedLibPath = "aetpkss1.dll"

success = pkcs11.Initialize()
If (success = 0) Then
    outFile.WriteLine(pkcs11.LastErrorText)
    WScript.Quit
End If

' Pass -1 for the slotID to open a session on the first non-empty slot.
slotID = -1

' Open a session.
readWrite = 1
success = pkcs11.OpenSession(slotID,readWrite)
If (success = 0) Then
    outFile.WriteLine(pkcs11.LastErrorText)
    WScript.Quit
End If

' Make it an authenticated session by calling Login.
' 
' If we don't authenticate, then we won't be able to see the private keys, and thus
' we won't know which certificates have an associated private key stored on the smart card.

' The smart card PIN is passed to the Login method.
' userType 1 indicates a "Normal User".
userType = 1
pin = "0000"
success = pkcs11.Login(userType,pin)
If (success = 0) Then
    outFile.WriteLine(pkcs11.LastErrorText)
    success = pkcs11.CloseSession()
    WScript.Quit
End If

' --------------------------------------------------------------------------

set cert = CreateObject("Chilkat.Cert")

' Find a certificate with an intended key usage.
' Possible key usages to find are:
' 
' DigitalSignature
' NonRepudiation
' KeyEncipherment
' DataEncipherment
' CertificateSigning
' CrlSigning
' 
' To find a cert having any one of several usages, pass a comma-separated list of usages:
success = pkcs11.FindCert("keyUsage","NonRepudiation,DigitalSignature",cert)
If (success = 1) Then
    outFile.WriteLine("Cert with private key: " & cert.SubjectCN)
Else
    outFile.WriteLine("No certificates having the intended key usage were found.")
End If

' --------------------------------------------------------------------------

' Revert to an unauthenticated session by calling Logout.
success = pkcs11.Logout()
If (success = 0) Then
    outFile.WriteLine(pkcs11.LastErrorText)
    success = pkcs11.CloseSession()
    WScript.Quit
End If

' When finished, close the session.
' It is important to close the session (memory leaks will occur if the session is not properly closed).
success = pkcs11.CloseSession()
If (success = 0) Then
    outFile.WriteLine(pkcs11.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine("Success.")

outFile.Close