Use an XmlCertVault for S/MIME Operations

See more MIME Examples

Loads a CMS/PKCS #7 encrypted S/MIME message and decrypts it back to the original MIME content.

UseCertVault sets an XmlCertVault as the single active source of certificates and private keys for S/MIME encryption, decryption, signing, and verification.

The file paths are relative to the application's current working directory. Absolute paths may also be used. Supply the paths appropriate to your own environment.

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

set mime = CreateObject("Chilkat.Mime")
success = mime.LoadMimeFile("qa_data/encrypted.eml")
If (success = 0) Then
    outFile.WriteLine(mime.LastErrorText)
    WScript.Quit
End If

'  Use an XmlCertVault as the source of certificates and private keys for S/MIME operations.  The
'  only argument is the vault.  Only one vault is active at a time.
set vault = CreateObject("Chilkat.XmlCertVault")
pfxPassword = "myPfxPassword"
success = vault.AddPfxFile("qa_data/recipient.pfx",pfxPassword)
If (success = 0) Then
    outFile.WriteLine(vault.LastErrorText)
    WScript.Quit
End If

success = mime.UseCertVault(vault)
If (success = 0) Then
    outFile.WriteLine(mime.LastErrorText)
    WScript.Quit
End If

'  Decryption (and signing/verification) now draws credentials from the vault.
success = mime.Decrypt()
If (success = 0) Then
    outFile.WriteLine(mime.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine("Decrypted using the certificate vault.")

outFile.Close