MIME S/MIME Encryption Algorithm Properties

See more MIME Examples

Demonstrates the properties that control S/MIME encryption: Pkcs7CryptAlg (the symmetric content-encryption algorithm), Pkcs7KeyLength (the content-encryption key length in bits), OaepPadding (whether RSAES-OAEP key transport is used instead of RSAES-PKCS1-v1_5), and the OAEP hash settings OaepHash and OaepMgfHash. The properties are configured before calling Encrypt.

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

set mime = CreateObject("Chilkat.Mime")
success = mime.SetBodyFromPlainText("This message will be encrypted.")
If (success = 0) Then
    outFile.WriteLine(mime.LastErrorText)
    WScript.Quit
End If

'  Pkcs7CryptAlg is the symmetric content-encryption algorithm.  Supported values are aes, aes-gcm,
'  des, 3des, and rc2.  The default is aes.
mime.Pkcs7CryptAlg = "aes"

'  Pkcs7KeyLength is the content-encryption key length in bits.  The default is 128.
mime.Pkcs7KeyLength = 256

'  OaepPadding selects the RSA key-transport padding.  The default is 0 (RSAES-PKCS1-v1_5).
'  Set 1 to use RSAES-OAEP, in which case the OAEP hash settings apply.
mime.OaepPadding = 1
mime.OaepHash = "sha256"
mime.OaepMgfHash = "sha256"

'  Load the recipient certificate (public key is sufficient for encrypting).
set cert = CreateObject("Chilkat.Cert")
success = cert.LoadFromFile("qa_data/recipient.cer")
If (success = 0) Then
    outFile.WriteLine(cert.LastErrorText)
    WScript.Quit
End If

'  Encrypt using the algorithm settings configured above.
success = mime.Encrypt(cert)
If (success = 0) Then
    outFile.WriteLine(mime.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine("Encrypted with " & mime.Pkcs7CryptAlg & " " & mime.Pkcs7KeyLength & "-bit key.")

outFile.Close