VBScript

Add an S/MIME Detached Signature

Demonstrates the Chilkat Mime.AddDetachedSignature method, which creates an S/MIME detached signature. The only argument is the signing Cert, which must have access to its private key. On success the entity becomes a multipart/signed with the content and a separate signature part.

Note: The file paths are relative to the application's current working directory. Absolute paths may also be used. Supply the paths appropriate to your own environment.

Background: A detached signature (multipart/signed) keeps the original content readable alongside a separate signature part — so recipients whose software does not understand S/MIME still see the message, they just cannot verify it. That backward compatibility makes detached the usual choice for signed email. The signer proves authorship with a certificate that carries its private key.

Chilkat VBScript Downloads

Download Chilkat for VBScript

VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

set mime = CreateObject("Chilkat.Mime")
success = mime.SetBodyFromPlainText("This message will be signed.")
If (success = 0) Then
    outFile.WriteLine(mime.LastErrorText)
    WScript.Quit
End If

'  Load the signing certificate (which must have access to its private key) from a PFX file.
'  The PFX password should come from a secure source rather than being hard-coded.
pfxPassword = "myPfxPassword"
set cert = CreateObject("Chilkat.Cert")
success = cert.LoadPfxFile("qa_data/signer.pfx",pfxPassword)
If (success = 0) Then
    outFile.WriteLine(cert.LastErrorText)
    WScript.Quit
End If

'  Create an S/MIME detached signature.  The object becomes a multipart/signed entity with the
'  original content and a separate signature part.
success = mime.AddDetachedSignature(cert)
If (success = 0) Then
    outFile.WriteLine(mime.LastErrorText)
    WScript.Quit
End If

success = mime.SaveMime("qa_output/signed.eml")
If (success = 0) Then
    outFile.WriteLine(mime.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine("Detached signature added.")

outFile.Close