VBScript

Subtract One MessageSet from Another

Demonstrates the Chilkat MessageSet.Subtract method, which removes from this set every identifier whose numeric value is also present in another MessageSet. The only argument is the other set. This example starts with ids 1:10, subtracts 2,4,6, and prints what remains.

Background: A common IMAP pattern is "process everything except what I've already handled." Subtract makes that a single call: remove the already-processed ids from a working set. The comparison is numeric only and this object's HasUids is preserved, so for meaningful results both sets should hold the same id type from the same mailbox. Passing the same object clears the set; passing an empty set changes nothing.

Chilkat VBScript Downloads

Download Chilkat for VBScript

VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

'  Demonstrates the MessageSet.Subtract method, which removes from this set every identifier
'  that is also present in another MessageSet.  The only argument is the other MessageSet.

set msgSet = CreateObject("Chilkat.MessageSet")

'  Start with messages 1 through 10.
success = msgSet.FromCompactString("1:10")
If (success = 0) Then
    outFile.WriteLine(msgSet.LastErrorText)
    WScript.Quit
End If

'  The identifiers that have already been processed and should be excluded.
set processed = CreateObject("Chilkat.MessageSet")
success = processed.FromCompactString("2,4,6")
If (success = 0) Then
    outFile.WriteLine(processed.LastErrorText)
    WScript.Quit
End If

'  Remove the already-processed identifiers from msgSet.
msgSet.Subtract processed

'  Show what remains.
remaining = msgSet.ToCompactString()
outFile.WriteLine(remaining)
'  Output: 1,3,5,7:10

outFile.Close