VBScript

Verify Email Recipients Without Sending

Demonstrates the Chilkat MailMan.VerifyRecips method, which begins the SMTP send process for an email, sends the recipient addresses to the SMTP server, and then aborts before sending the message content. Recipient addresses rejected by the server are returned in the StringArray. This example checks two recipients and lists any that were rejected.

Background: During an SMTP transaction each recipient is offered with a RCPT TO command, and the server accepts or rejects it before any message content is transferred. VerifyRecips exploits that: it runs the transaction just far enough to collect those verdicts, then aborts — letting you validate an address list without actually delivering mail. Note that many servers accept everything at this stage and bounce later, so a clean result is not a guarantee of deliverability.

Chilkat VBScript Downloads

Download Chilkat for VBScript

VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

'  Demonstrates the MailMan.VerifyRecips method, which begins the SMTP send process for an
'  email, sends the recipient addresses to the SMTP server, and then aborts before sending
'  the message content.  Recipient addresses rejected by the server are returned in the
'  StringArray.

set mailman = CreateObject("Chilkat.MailMan")

'  Configure the SMTP server connection.
mailman.SmtpHost = "smtp.example.com"
mailman.SmtpPort = 465
mailman.SmtpSsl = 1
mailman.SmtpUsername = "user@example.com"
mailman.SmtpPassword = "myPassword"

'  Build an email with the recipients to verify.
set email = CreateObject("Chilkat.Email")
email.Subject = "Recipient check"
email.From = "alice@example.com"
success = email.AddTo("Bob","bob@example.com")
success = email.AddTo("Nobody","nobody@example.com")

'  Ask the server which recipients it will accept.  Rejected addresses are returned.
set badAddrs = CreateObject("Chilkat.StringArray")
success = mailman.VerifyRecips(email,badAddrs)
If (success = 0) Then
    outFile.WriteLine(mailman.LastErrorText)
    WScript.Quit
End If

n = badAddrs.Count
outFile.WriteLine("Rejected recipients: " & n)

For i = 0 To n - 1
    outFile.WriteLine(badAddrs.GetString(i))
Next

'  Note: Explicitly connecting/authenticating is optional.  Chilkat MailMan automatically
'  connects and authenticates -- using the property settings above -- whenever a server
'  operation requires it.  Calling the explicit connect/authenticate methods can still be
'  helpful to determine whether a failure occurs while connecting or while authenticating.

outFile.Close