VBScript

Use an Existing Socket SSH Tunnel

Demonstrates the Chilkat MailMan.UseSshTunnel method, which configures MailMan to use an existing SSH tunnel provided by a Socket object for its SMTP and POP3 connections. This example opens and authenticates a tunnel on a Socket, hands it to MailMan, and then verifies an SMTP login through it.

Background: Sharing one already-established SSH tunnel across objects avoids opening (and authenticating) a separate SSH connection for every component that needs to reach the remote network. Here the tunnel lives on a Socket object, which MailMan then routes its SMTP/POP3 traffic through. It is the Socket-based sibling of UseSsh, which shares an Ssh object instead.

Chilkat VBScript Downloads

Download Chilkat for VBScript

VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

'  Demonstrates the MailMan.UseSshTunnel method, which configures MailMan to use an existing
'  SSH tunnel provided by a Socket object for its SMTP and POP3 connections.

'  Open and authenticate the SSH tunnel using a Socket object.
set sshTunnel = CreateObject("Chilkat.Socket")
success = sshTunnel.SshOpenTunnel("ssh.example.com",22)
If (success = 0) Then
    outFile.WriteLine(sshTunnel.LastErrorText)
    WScript.Quit
End If

success = sshTunnel.SshAuthenticatePw("sshUser","sshPassword")
If (success = 0) Then
    outFile.WriteLine(sshTunnel.LastErrorText)
    WScript.Quit
End If

set mailman = CreateObject("Chilkat.MailMan")

'  Configure the SMTP server connection.  These connections will travel through the tunnel.
mailman.SmtpHost = "smtp.example.com"
mailman.SmtpPort = 465
mailman.SmtpSsl = 1
mailman.SmtpUsername = "user@example.com"
mailman.SmtpPassword = "myPassword"

'  Tell MailMan to route its connections through the existing tunnel.
success = mailman.UseSshTunnel(sshTunnel)
If (success = 0) Then
    outFile.WriteLine(mailman.LastErrorText)
    WScript.Quit
End If

'  SMTP operations now travel through the shared SSH tunnel.
success = mailman.VerifySmtpLogin()
If (success = 0) Then
    outFile.WriteLine(mailman.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine("Authenticated with the SMTP server through the SSH tunnel.")

outFile.Close