VBScript

Use an Existing Ssh Object as the Tunnel

Demonstrates the Chilkat MailMan.UseSsh method, which configures MailMan to use an existing SSH tunnel provided by an Ssh object for its SMTP and POP3 connections. This example connects and authenticates an Ssh object separately, hands it to MailMan, and then performs a POP3 operation through it.

Background: Rather than having MailMan open its own tunnel (SshOpenTunnel), you can manage the SSH connection yourself and share it. That is valuable when several Chilkat objects must reach the same remote network — they all ride one authenticated SSH connection instead of each opening its own — and it enables advanced setups such as multi-hop SSH, where the Ssh object is already chained through intermediate servers.

Chilkat VBScript Downloads

Download Chilkat for VBScript

VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

'  Demonstrates the MailMan.UseSsh method, which configures MailMan to use an existing SSH
'  tunnel provided by an Ssh object for its SMTP and POP3 connections.

'  Establish the SSH connection separately, using an Ssh object.
set ssh = CreateObject("Chilkat.Ssh")
success = ssh.Connect("ssh.example.com",22)
If (success = 0) Then
    outFile.WriteLine(ssh.LastErrorText)
    WScript.Quit
End If

success = ssh.AuthenticatePw("sshUser","sshPassword")
If (success = 0) Then
    outFile.WriteLine(ssh.LastErrorText)
    WScript.Quit
End If

set mailman = CreateObject("Chilkat.MailMan")

'  Configure the POP3 server connection.  These connections will travel through the tunnel.
mailman.MailHost = "pop.example.com"
mailman.MailPort = 995
mailman.PopSsl = 1
mailman.PopUsername = "user@example.com"
mailman.PopPassword = "myPassword"

'  Tell MailMan to route its connections through the already-connected Ssh object.
success = mailman.UseSsh(ssh)
If (success = 0) Then
    outFile.WriteLine(mailman.LastErrorText)
    WScript.Quit
End If

'  POP3 operations now travel through the shared SSH connection.
count = mailman.GetMailboxCount()
If (count < 0) Then
    outFile.WriteLine("Failed to get the mailbox count.")
Else
    outFile.WriteLine("Mailbox count: " & count)
End If

ssh.Disconnect 

outFile.Close