VBScript

Provide a Certificate Vault to MailMan

Demonstrates the Chilkat MailMan.UseCertVault method, which provides an XML certificate vault to be searched for certificates and private keys when MailMan performs operations such as encryption, decryption, signing, or signature verification. This example builds a vault from a PFX, attaches it, and fetches a message that Chilkat can decrypt using the vault.

Background: A certificate vault is a portable, in-memory store of certificates and private keys. Rather than wiring up a specific certificate for each operation, you load your credentials into one XmlCertVault and hand it to MailMan, which then searches it automatically whenever a key is needed. This is especially useful on platforms without an OS certificate store, or when one application handles several identities.

Chilkat VBScript Downloads

Download Chilkat for VBScript

VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

'  Demonstrates the MailMan.UseCertVault method, which provides an XML certificate vault to
'  be searched for certificates and private keys when MailMan performs operations such as
'  encryption, decryption, signing, or signature verification.

set mailman = CreateObject("Chilkat.MailMan")

'  Configure the POP3 server connection.
mailman.MailHost = "pop.example.com"
mailman.MailPort = 995
mailman.PopSsl = 1
mailman.PopUsername = "user@example.com"
mailman.PopPassword = "myPassword"

'  Build a certificate vault from a PFX (certificate + private key).
set vault = CreateObject("Chilkat.XmlCertVault")
success = vault.AddPfxFile("qa_data/certs/certs.pfx","pfx_password")
If (success = 0) Then
    outFile.WriteLine(vault.LastErrorText)
    WScript.Quit
End If

'  Make the vault available to MailMan for crypto operations.
success = mailman.UseCertVault(vault)
If (success = 0) Then
    outFile.WriteLine(mailman.LastErrorText)
    WScript.Quit
End If

'  Fetch a message; Chilkat draws on the vault if a private key is needed to decrypt it.
set email = CreateObject("Chilkat.Email")
success = mailman.FetchOne(0,0,1,email)
If (success = 0) Then
    outFile.WriteLine(mailman.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine("Decrypted = " & email.Decrypted)

'  Note: The path "qa_data/certs/certs.pfx" is a relative local filesystem path,
'  relative to the current working directory of the running application.

'  Note: Explicitly connecting/authenticating is optional.  Chilkat MailMan automatically
'  connects and authenticates -- using the property settings above -- whenever a server
'  operation requires it.  Calling the explicit connect/authenticate methods can still be
'  helpful to determine whether a failure occurs while connecting or while authenticating.

outFile.Close