VBScript

Get Accepted and Rejected SMTP Recipients

Demonstrates the Chilkat MailMan.SmtpRecipientsLog method, which returns the list of recipient email addresses accepted or rejected by the SMTP server during the most recent email-send operation. Pass true to get the rejected list or false to get the accepted list. This example sends a message to two recipients and reports both lists.

Background: A send to multiple recipients is not necessarily all-or-nothing: the server judges each RCPT TO separately, so a message can be delivered to some addresses while others are refused. Inspecting these lists after a send tells you exactly who was accepted and who was not — essential for reporting partial failures accurately or flagging bad addresses in a mailing list, rather than assuming a successful send reached everyone.

Chilkat VBScript Downloads

Download Chilkat for VBScript

VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

'  Demonstrates the MailMan.SmtpRecipientsLog method, which returns the list of recipient
'  email addresses accepted or rejected by the SMTP server during the most recent email-send
'  operation.  Pass 1 for the rejected list, or 0 for the accepted list.

set mailman = CreateObject("Chilkat.MailMan")

'  Configure the SMTP server connection.
mailman.SmtpHost = "smtp.example.com"
mailman.SmtpPort = 465
mailman.SmtpSsl = 1
mailman.SmtpUsername = "user@example.com"
mailman.SmtpPassword = "myPassword"

'  Send an email to two recipients.
set email = CreateObject("Chilkat.Email")
email.Subject = "Test email"
email.From = "alice@example.com"
success = email.AddTo("Bob","bob@example.com")
success = email.AddTo("Carol","carol@example.com")
email.Body = "Hello!"
success = mailman.SendEmail(email)
If (success = 0) Then
    outFile.WriteLine(mailman.LastErrorText)
    WScript.Quit
End If

'  Get the recipients the server accepted (rejected = 0).
set accepted = CreateObject("Chilkat.StringTable")
mailman.SmtpRecipientsLog 0,accepted
outFile.WriteLine("Accepted recipients: " & accepted.Count)

'  Get the recipients the server rejected (rejected = 1).
set rejected = CreateObject("Chilkat.StringTable")
mailman.SmtpRecipientsLog 1,rejected
n = rejected.Count
outFile.WriteLine("Rejected recipients: " & n)

For i = 0 To n - 1
    outFile.WriteLine(rejected.StringAt(i))
Next

'  Note: Explicitly connecting/authenticating is optional.  Chilkat MailMan automatically
'  connects and authenticates -- using the property settings above -- whenever a server
'  operation requires it.  Calling the explicit connect/authenticate methods can still be
'  helpful to determine whether a failure occurs while connecting or while authenticating.

outFile.Close