VBScript

Get JSON Details from the Last MailMan Call

Demonstrates the Chilkat MailMan.GetLastJsonData method, which copies any structured JSON details produced by the immediately preceding method call into a JsonObject. Not every MailMan method produces JSON details, and the method must be called immediately after the call of interest. This example sends an email and then retrieves the JSON details, which include the negotiated TLS version and parameters, the SMTP server's last response and status code, and the result of SMTP authentication.

Tip: JSON parsing code for this result can be generated at Chilkat Tools.

Background: Some Chilkat methods gather structured diagnostic information alongside their normal result — details that are far more useful as data than as a log string. GetLastJsonData exposes that as a JsonObject you can query programmatically, making it easy to record exactly which TLS version was negotiated or which SMTP status code came back. Because it reflects only the most recent call, retrieve it right away: any subsequent MailMan method may replace it.

Chilkat VBScript Downloads

Download Chilkat for VBScript

VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

'  Demonstrates the MailMan.GetLastJsonData method, which copies any structured JSON details
'  produced by the immediately preceding method call into a JsonObject.  Not every MailMan
'  method produces JSON details, and it must be called immediately after the method of
'  interest.

set mailman = CreateObject("Chilkat.MailMan")

'  Configure the SMTP server connection.
mailman.SmtpHost = "smtp.example.com"
mailman.SmtpPort = 465
mailman.SmtpSsl = 1
mailman.SmtpUsername = "user@example.com"
mailman.SmtpPassword = "myPassword"

'  Send an email.
set email = CreateObject("Chilkat.Email")
email.Subject = "Test email"
email.From = "alice@example.com"
success = email.AddTo("Bob","bob@example.com")
email.Body = "Hello!"
success = mailman.SendEmail(email)
If (success = 0) Then
    outFile.WriteLine(mailman.LastErrorText)
    WScript.Quit
End If

'  Immediately retrieve any JSON details produced by the send.
set json = CreateObject("Chilkat.JsonObject")
mailman.GetLastJsonData json

'  Emit non-compact (indented) JSON for readability.
json.EmitCompact = 0
outFile.WriteLine(json.Emit())

'  Sample output:
'  
'    {
'      "tls": {
'        "params": {
'          "sniHostname": "mail.chilkat.io",
'          "allowConnectionOnlyIfServerChooses": "SSL 3.0 or higher"
'        },
'        "negotiatedTlsVersion": "TLS 1.3"
'      },
'      "smtp": {
'        "lastResponse": "250 OK id=1wkjeT-00000002yb4-0uve",
'        "lastStatus": 250
'      },
'      "smtpAuth": {
'        "user": "test@chilkat.io",
'        "method": "login",
'        "statusCode": 235,
'        "success": true
'      }
'    }
'  
'  JSON parsing code for this result can be generated at Chilkat's online tool:
'  https://tools.chilkat.io/jsonParse

'  Note: Explicitly connecting/authenticating is optional.  Chilkat MailMan automatically
'  connects and authenticates -- using the property settings above -- whenever a server
'  operation requires it.  Calling the explicit connect/authenticate methods can still be
'  helpful to determine whether a failure occurs while connecting or while authenticating.

outFile.Close