VBScript

Verify JWT with EdDSA / Ed25519 Signature

See more JSON Web Token (JWT) Examples

Note: This example requires Chilkat v9.5.0.84 or greater.

Demonstrates how to verify a JWT that was signed using an Ed25519 private key.

This example verifies the EdDSA signature. It also does the following:

• Checks to see if the time constraints ("nbf" and "exp") are valid.
• Recovers the original JOSE header.
• Recovers the original data.

VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' Demonstrates how to verify a JWT with an EdDSA/Ed25519 Signature
' *** Requires Chilkat v9.5.0.84 or greater.

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' Use this Ed25519 public key for verification

jsonPubKey = "{""kty"": ""OKP"",""alg"": ""EdDSA"",""crv"": ""Ed25519"",""x"": ""11qYAYKxCrfVS_7TyWQHOg7hcvPapiMlrwIaaPcHURo""}"

set pubKey = CreateObject("Chilkat.PublicKey")
success = pubKey.LoadFromString(jsonPubKey)
If (success = 0) Then
    outFile.WriteLine(pubKey.LastErrorText)
    WScript.Quit
End If

set jwt = CreateObject("Chilkat.Jwt")
token = "eyJhbGciOiJFZERTQSJ9.RXhhbXBsZSBvZiBFZDI1NTE5IHNpZ25pbmc.hgyY0il_MGCjP0JzlnLWG1PPOt7-09PGcvMg3AIbQR6dWbhijcNR4ki4iylGjg5BhVsPt9g7sVvpAr_MuM0KAg"

' First verify the signature.
sigVerified = jwt.VerifyJwtPk(token,pubKey)
outFile.WriteLine("verified: " & sigVerified)

If (sigVerified = 0) Then
    outFile.WriteLine(jwt.LastErrorText)
    WScript.Quit
End If

' Let's see if the time constraints, if any, are valid.
' The above JWT was created on the afternoon of 16-May-2016, with an expiration of 1 hour.
' If the current system time is before the "nbf" time, or after the "exp" time,
' then IsTimeValid will return false/0.
' Also, we'll allow a leeway of 60 seconds to account for any clock skew.
' Note: If the token has no "nbf" or "exp" claim fields, then IsTimeValid is always true.
leeway = 60
bTimeValid = jwt.IsTimeValid(token,leeway)
outFile.WriteLine("time constraints valid: " & bTimeValid)

' Recover the original data (the payload).
payload = jwt.GetPayload(token)
outFile.WriteLine(payload)

' Recover the original JOSE header in the same way:
joseHeader = jwt.GetHeader(token)
outFile.WriteLine(joseHeader)

outFile.Close